1

我希望能再在这里得到帮助。这是我的示例输入 XML：

<Report>
  <RecordValues>
    <Record>
        <FieldValue fieldName="firm_name" fieldValue="Firm_1"/>
        <FieldValue fieldName="firm_number" fieldValue="11"/>
        <FieldValue fieldName="prepared_by" fieldValue="PARKER"/>
        <FieldValue fieldName="contact_number" fieldValue="123456789"/>
        <FieldValue fieldName="trade_date" fieldValue="2010-10-17"/>
        <FieldValue fieldName="symbol" fieldValue="ADM"/>
    </Record>
    <Record>
    <FieldValue fieldName="firm_name" fieldValue="Firm_1"/>
        <FieldValue fieldName="firm_number" fieldValue="11"/>
        <FieldValue fieldName="prepared_by" fieldValue="PARKER"/>
        <FieldValue fieldName="contact_number" fieldValue="123456789"/>
        <FieldValue fieldName="trade_date" fieldValue="2010-10-16"/>
        <FieldValue fieldName="symbol" fieldValue="ACW"/>
    </Record>
    <Record>
        <FieldValue fieldName="firm_name" fieldValue="Firm_2"/>
        <FieldValue fieldName="firm_number" fieldValue="12"/>
        <FieldValue fieldName="prepared_by" fieldValue="EDWARDS"/>
        <FieldValue fieldName="contact_number" fieldValue="123456780"/>
        <FieldValue fieldName="trade_date" fieldValue="2010-10-19"/>
        <FieldValue fieldName="symbol" fieldValue="ADS"/>
    </Record>
  </RecordValues>
</Report>

这是我需要得到的输出：

A Firm_1 11
B PARKER 123456789
C 2010-10-17 ADM
C 2010-10-16 ACW
T 4
A Firm_2 12
B EDWARDS 123456780
C 2010-10-19 ADS
T 3

如您所见，我需要按“firm_name”或“firm_number”对记录进行分组。每个组必须有一个“A”类型的记录、一个“B”类型的记录和多个“C”类型的记录。记录“T”是没有记录“T”的每个组的总和。输入 XML 已排序。我找到了对记录进行分组的Muenchian Method，但没有成功。显然我做错了什么。这是我写的 XSLT：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="text"/>
   <xsl:strip-space elements="*"/>

   <xsl:key name="value-by-firm" match="Report/RecordValues/Record/FieldValue" use="firm_number"/>
  <xsl:template match="Record">
   <xsl:for-each select="FieldValue/@fieldValue[count(. | key('value-by-firm', firm_number))]">
    <xsl:text>A </xsl:text>
    <xsl:value-of select="firm_name"/>
    <xsl:text> </xsl:text>
    <xsl:value-of select="firm_number"/>
    <xsl:text>&#xA;</xsl:text>
    <xsl:text>B </xsl:text>
    <xsl:value-of select="prepared_by"/>
    <xsl:text> </xsl:text>
    <xsl:value-of select="contact_number"/>
    <xsl:text>&#xA;</xsl:text>
    <xsl:for-each select="key('value-by-firm', firm_number)">
      <xsl:text>C </xsl:text>
      <xsl:value-of select="trade_date"/>
      <xsl:text> </xsl:text>
      <xsl:value-of select="symbol"/>
      <xsl:text>&#xA;</xsl:text>
   </xsl:for-each>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

也许还有另一种方法可以做到这一点。提前致谢。

4

2 回答 2

1

这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:key name="kRecordByFirmAndContact" match="Record"
             use="concat(FieldValue[@fieldName='firm_number']
                            /@fieldValue,
                         '+',
                         FieldValue[@fieldName='contact_number']
                            /@fieldValue)"/>
    <xsl:template
         match="Record
                   [count(.|key('kRecordByFirmAndContact',
                                concat(FieldValue
                                          [@fieldName='firm_number']
                                          /@fieldValue,
                                       '+',
                                       FieldValue
                                          [@fieldName='contact_number']
                                          /@fieldValue))[1])
                    = 1 ]">
        <xsl:variable name="vRecords"
                      select="key('kRecordByFirmAndContact',
                                  concat(FieldValue
                                            [@fieldName='firm_number']
                                            /@fieldValue,
                                         '+',
                                         FieldValue
                                            [@fieldName='contact_number']
                                            /@fieldValue))"/>
        <xsl:value-of select="concat('A ',
                                     *[@fieldName='firm_name']
                                      /@fieldValue,
                                     ' ',
                                     *[@fieldName='firm_number']
                                      /@fieldValue,
                                     '&#xA;',
                                     'B ',
                                     *[@fieldName='prepared_by']
                                      /@fieldValue,
                                     ' ',
                                     *[@fieldName='contact_number']
                                      /@fieldValue,
                                     '&#xA;')"/>
        <xsl:apply-templates select="$vRecords" mode="RecordC"/>
        <xsl:value-of select="concat('T ',count($vRecords) + 2,'&#xA;')"/>
    </xsl:template>
    <xsl:template match="Record" mode="RecordC">
        <xsl:value-of select="concat('C ',
                                     *[@fieldName='trade_date']
                                      /@fieldValue,
                                     ' ',
                                     *[@fieldName='symbol']
                                      /@fieldValue,
                                     '&#xA;')"/>
    </xsl:template>
</xsl:stylesheet>

输出：

A Firm_1 11
B PARKER 123456789
C 2010-10-17 ADM
C 2010-10-16 ACW
T 4
A Firm_2 12
B EDWARDS 123456780
C 2010-10-19 ADS
T 3

注意：如您所见，这并不复杂，但您的架构使代码如此冗长......这看起来像用于数据转储的 M$ XML 格式。

于 2010-12-13T20:48:15.487 回答
1

您正在对“错误”的事物进行分组，并且错误地使用了这些组。

  • 您正在尝试对Record元素进行分组。因此，那些应该由您匹配xsl:key（该use=...属性应该引用公司名称）
  • 分组技巧通过只处理每个组一次来起作用。您不能显式处理 an 中的每个键，xsl:key因此您可以处理所有值并忽略组中除第一个值之外的所有值 - 并在那里进行整个组的处理。这意味着您的 foreach 应该选择与 dos 相同的元素xsl:key并添加节点 test ala [count(. | reference-to-group[1]) = 1]- 在这里，您忘记了[1]and= 1部分。

然后是固定的 XSLT 文件（请注意，字段查找也略有变化，我没有添加T计算：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:strip-space elements="*"/>

  <xsl:key name="value-by-firm" match="/Report/RecordValues/Record" use="FieldValue[@fieldName='firm_number']/@fieldValue"/>
  <xsl:template match="/">
    <xsl:for-each select="/Report/RecordValues/Record[count(. | key('value-by-firm', FieldValue[@fieldName='firm_number']/@fieldValue)[1]) = 1]">
      <xsl:text>A </xsl:text>
      <xsl:value-of select="FieldValue[@fieldName='firm_name']/@fieldValue"/>
      <xsl:text> </xsl:text>
      <xsl:value-of select="FieldValue[@fieldName='firm_number']/@fieldValue"/>
      <xsl:text>&#xA;</xsl:text>
      <xsl:text>B </xsl:text>
      <xsl:value-of select="FieldValue[@fieldName='prepared_by']/@fieldValue"/>
      <xsl:text> </xsl:text>
      <xsl:value-of select="FieldValue[@fieldName='contact_number']/@fieldValue"/>
      <xsl:text>&#xA;</xsl:text>
      <xsl:for-each select="key('value-by-firm', FieldValue[@fieldName='firm_number']/@fieldValue)">
        <xsl:text>C </xsl:text>
        <xsl:value-of select="FieldValue[@fieldName='trade_date']/@fieldValue"/>
        <xsl:text> </xsl:text>
        <xsl:value-of select="FieldValue[@fieldName='symbol']/@fieldValue"/>
        <xsl:text>&#xA;</xsl:text>
      </xsl:for-each>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

编辑：最后一点：鉴于此数据模式，您所做的并不是 XSLT 的强项之一。看起来您的数据结构可以自然地转换为更清晰的模式（例如，其中名称-值对由 XML 的自然名称-值对表示；即属性）。或者，您可能希望将其导入“真正的”编程语言（这些数据几乎肯定来自该语言），其中不表示 FieldValue 元素以及 fieldName 和 fieldValue 属性等所有杂乱无章的东西。基本上; 尽管使用 XML+XSLT 可以做到这一点，但您最终会得到一个更复杂、更脆弱的解决方案，而不是使用更自然的表示形式来表示它并使用更自然的工具来处理它。

于 2010-12-13T19:30:39.443 回答