windows - cmd 默认为 F: 驱动器

Question

当我在笔记本电脑上打开 cmd 时，它默认为 F: 驱动器。这让我很困扰，有没有人知道它是怎么做到的，或者如何让它回到它默认打开 C: 驱动器的位置？

score 8 · Accepted Answer

8

使用命令

C:

更改为驱动器 C。它当然适用于任何驱动器号。

于 2015-12-12T07:32:17.950 回答

score 3 · Accepted Answer

http://blog.stevienova.com/2007/04/08/change-your-default-cmd-prompt-path/

有时，当您开始-> 运行时，您的路径将是您不想要的 CMD。在活动目录或 NT 域中，有时您的默认主路径可能是网络驱动器。当您离线或在线后离线时，这不是很好。CMD 提示设置为你无法到达的地方。

要更改路径，您可以编辑注册表（风险自负）

Windows 注册表编辑器版本 5.00

[HKEY_CURRENT_USERSoftwareMicrosoftCommand Processor] “自动运行”=”c:”</p>
这将更改您的 c: 驱动器的路径。

score 3 · Accepted Answer

非常小的问题：如果您使用的是 Windows 7，则不需要 cmdhere powertoy，它内置于资源管理器中。

您只需在 Windows 资源管理器中导航到一个目录，然后按住 shift 键并右键单击。“在此处打开命令窗口”是上下文菜单上的选项之一。

在特定目录中打开 cmd.exe 时，我只需创建 cmd.exe 的快捷方式，然后在快捷方式属性中将“开始位置：”设置为我希望它开始的驱动器/目录。

使用快捷方式可以让我根据我的用途自定义 cmd.exe 窗口。对于正常的文件编辑/查看，我使用 180x60 窗口和适当的字体，但是当我想读取/搜索日志文件时，我有一个快捷方式，可以打开一个 260x100 窗口和较小的字体。这样我就可以查看最长的日志文件行，而无需使用水平滚动。

score 2 · Accepted Answer

我相信它默认为%HOMEDRIVE%\%HOMEPATH%如此，如果您可以使用那些可能是一个选项的环境变量。我无法在我公司的网络上编辑这些环境变量，所以我不得不使用AutoRun将其更改为正常的东西。

score 1 · Accepted Answer

快速回答：cmd /kc：

让它“自动”的长答案：http: //windowsxp.mvps.org/autoruncmd.htm

score 1 · Accepted Answer

在 RegEdit.exe 我创建了一个字符串：

HKEY_CURRENT_USER\Software\Microsoft\Command Processor\AutoRun

我用于自动运行的值是“D：”

score 1 · Accepted Answer

在开始屏幕/菜单上，输入“cmd”，右键单击它并选择“打开文件 - 位置”。
在打开的窗口中，右键单击“命令提示符”图标，选择“属性”，然后将“开始于”属性编辑为所需的路径。我以“C:\”为例

score 0 · Accepted Answer

0

如果您从快捷方式打开它，请更改快捷方式的工作目录。

于 2008-09-04T17:37:00.177 回答

score 0 · Accepted Answer

除了其他答案之外，还有一个用于 XP 的不错的 powertoy，称为“在此处打开命令窗口”。当您在文件夹内单击以使用该目录作为起始路径打开命令窗口时，它会在您的右键单击上下文菜单中添加一个选项。

http://www.microsoft.com/windowsxp/Downloads/powertoys/Xppowertoys.mspx

score 0 · Accepted Answer

我遇到了一个类似的问题，其中 cmd 总是会在特定目录中打开（在运行调用 cmd 的脚本时很烦人）。处理此问题的最佳方法是编辑您的自动运行设置。Raymond Chen 在这里有一篇很好的文章：http: //blogs.msdn.com/oldnewthing/archive/2007/11/21/6447771.aspx

总结是，当您启动命令外壳时，它会检查自动运行注册表项，并执行存储在那里的命令。它检查的注册表项是：

HKEY_LOCAL_MACHINE\Software\Microsoft\Command Processor\AutoRun
    and/or
HKEY_CURRENT_USER\Software\Microsoft\Command Processor\AutoRun

score 0 · Accepted Answer

一些答案已经提到 AutoRun 作为解决方案。
但这可能非常危险，因为 AutoRun 条目将为任何新的 cmd.exe 实例执行（只有管道忽略 AutoRun）。

一个失败的简单示例：

cd /d E:\myPath
FOR /F "delims=" %%Q in ('dir') do echo - %%Q

，AutoRun=C:这显示了驱动器当前路径的内容C:

您仍然可以使用 AutoRun，但它应该是一个批处理脚本，用于检查它是否被称为交互式、通过FOR/F或拖放。

@echo off
REM *** To enable this script, call it by <scriptName> --install

setlocal EnableDelayedExpansion
REM *** ALWAYS make a copy of the complete CMDCMDLINE, else you destroy the original!!!
set "_ccl_=!cmdcmdline!"

REM *** The check is necessary to distinguish between a new cmd.exe instance for a user or for a "FOR /F" sub-command
if "!_ccl_:~1,-2!" == "!comspec!" (
    REM ***** INTERACTIVE ****

    REM *** %1 contains only data, when the script itself was called from the command line
    if "%~1" NEQ "" (
        goto :direct_call
    )

    endlocal
    doskey /macrofile="%~dp0\cmdMacros.mac"
    echo ********************************************************************
    echo * AutoRun executed from "%~f0"
    echo * Macros loaded from "%~dp0\cmdMacros.mac"
    echo ********************************************************************
    cd /d C:\myPath
) ELSE (
    REM *** Called by a FOR command, by an explorer click or a drag & drop operation
    REM *** Handle PROBLEMATIC Drag&Drop content, if necessary
    endlocal
)
exit /b


:direct_call
if "%~1" == "--install" (
    reg add "HKEY_CURRENT_USER\Software\Microsoft\Command Processor" /v "AutoRun" /t REG_SZ /d "%~f0"
    exit /b
) 

if "%~1" == "--show" (  
    reg query "HKEY_CURRENT_USER\Software\Microsoft\Command Processor" /v AutoRun
    exit /b
)

if "%~1" == "--remove" (
    reg DELETE "HKEY_CURRENT_USER\Software\Microsoft\Command Processor" /v AutoRun /f
)
exit /b

windows - cmd 默认为 F: 驱动器

11 回答 11

Related

Reference