0

我正在研究 Peter Seibel 的Practical Common Lisp中的 MP3 数据库示例。Seibel 演示了如何使用宏来缩短where函数的代码；所以现在，我正在尝试使用宏来缩短update函数的代码。（包含该update函数的原始版本以供参考。）当我运行我的代码时，以下错误源自倒数第二行 -

*** - CAR: TERMS is not a list

我究竟做错了什么？这是我的代码。

(defvar *db* nil)
(defun add-record (cd) 
  (push cd *db*))

(defun dump-db ()
  (dolist (cd *db*)
    (format t "~{~a:~10t~a~%~}~%" cd)))

(defun make-cd (title artist rating ripped)
  (list :title title :artist artist :rating rating :ripped ripped))

(defun prompt-read (prompt)
  (format *query-io* "~a: " prompt)
  (force-output *query-io*)
  (read-line *query-io*))

(defun prompt-for-cd ()
  (make-cd
    (prompt-read "Title")
    (prompt-read "Artist")
    (or (parse-integer (prompt-read "Rating") :junk-allowed t) 0)
    (y-or-n-p "Ripped [y/n]: ")))

(defun add-cds ()
  (loop (add-record (prompt-for-cd) )
        (if (not (y-or-n-p "Another? [y/n]: ")) (return) )))

(defun save-db (filename)
  (with-open-file (out filename
                       :direction :output
                       :if-exists :supersede)
                  (with-standard-io-syntax
                    (print *db* out))))

(defun load-db (filename)
  (with-open-file (in filename)
                  (with-standard-io-syntax
                    (setf *db* (read in) ))))

(defun select (selector-fn)
  (remove-if-not selector-fn *db*))

(defun make-comparison-expr (field value)
  `(equal (getf cd ,field) ,value))

(defun make-comparison-list (func fields)
  (loop while fields
        collecting (funcall func (pop fields) (pop fields))))

(defmacro where (&rest clauses)
  `#'(lambda (cd) (and ,@(make-comparison-list 'make-comparison-expr clauses))))

(defun make-update-expr (field value)
  `(setf (getf row ,field) ,value))

(defmacro make-update-list (fields)
  (make-comparison-list 'make-update-expr fields))

(defun update (selector-fn &rest terms)
  (print (type-of terms))
  (setf *db*
        (mapcar
          #'(lambda (row)
             (when (funcall selector-fn row)
               (make-update-list terms))
             row)
          *db*)))

;(defun update (selector-fn &key title artist rating (ripped nil ripped-p))
;  (setf *db*
;        (mapcar
;          #'(lambda (row)
;             (when (funcall selector-fn row)
;               (if title    (setf (getf row :title) title) )
;               (if artist   (setf (getf row :artist) artist) )
;               (if rating   (setf (getf row :rating) rating) )
;               (if ripped-p (setf (getf row :ripped) ripped) ))
;             row)
;          *db*)))

(defun delete-rows (selector-fn)
  (setf *db* (remove-if selector-fn *db*)))

;(loop (print (eval (read))))
(add-record (make-cd "Be" "Common" 9 nil))
(add-record (make-cd "Like Water for Chocolate" "Common" 9 nil))
(add-record (make-cd "Be" "Beatles" 9 nil))

(dump-db)
(update (where :artist "Common" :title "Be") :rating 8)
(dump-db)

- - -编辑 - - -

我想到了。解决方案是制作update一个宏并制作make-update-list一个函数。这样，make-update-list可以在运行时评估字段，并且update仍然可以抽象出一些乏味的 if 语句。以下是更新后的update内容make-update-list：

(defun make-update-list (fields)
  (make-comparison-list 'make-update-expr fields))

(defmacro update (selector-fn &rest terms)
  `(setf *db*
        (mapcar
          #'(lambda (row)
             (when (funcall ,selector-fn row)
               ,@(make-update-list terms))
             row)
          *db*)))
4

2 回答 2

4

宏扩展make-update-list是在一个单独的阶段（称为“宏扩展阶段”）完成的——这发生在一段代码被编译或加载的时候；在这种情况下，我们谈论的是编译/加载update. 宏被扩展并fields绑定到符号 terms，该符号（符号本身）用作make-comparison-list;中的值 我想那不是你所期望的。

注意，如果你逐行编译文件（C-c C-c在 Emacs + SLIME 中），它会在编译过程中告诉你update宏扩展失败，因为“值 TERMS 不是 LIST 类型”。

通常，将宏视为接受未经计算的参数的函数-即，一个表单(make-update-list foo)将被扩展，宏参数的fields值绑定到foo. 您在这里尝试实现的目标 - 基于运行时值的代码生成 - 有点难以做到。

于 2017-05-21T16:28:13.497 回答
2

您正在尝试获取car符号的 ！

> (car 'terms)
*** - CAR: TERMS is not a list

把宏想象成一个函数，当使用它时，它会在任何地方用宏函数的结果替换代码。此时变量只是符号，除此之外没有任何意义。

当你这样做时(make-update-list terms)，它会调用宏函数，参数fields是你传递的符号，即terms. 由于它是一个符号，因此无法像您尝试的那样对其进行迭代。当它肯定是一个列表时，你可以在运行时对其进行迭代，但作为一个宏，它不是一个列表，直到你传递一个像(make-update-list (title artist rating ripped)).

如果它在运行时是动态的，那么您的宏需要扩展为在运行时发挥其大部分魔力的代码。因此，宏只是一个源代码重写服务，不应该与运行时可能存在的变量有任何关系，因为它已经完成了它的工作。

于 2017-05-21T23:12:28.280 回答