1

我正在将 CSound 嵌入到 Lisp 中。CSound 是一个音乐合成（以及更多）开源软件。

它有一个相当简单的（脚本）语言。上面的链接提供了快速入门（10 分钟阅读）。目前我正在研究作业部分（这是 csound 语言的很大一部分）。

这是我的代码：

(defparameter *assign-statements* nil)

(defmacro assign (_name value &optional (rate 'i))
  (let* ((name (if (typep _name 'symbol) _name (eval _name)))
         (var (symb (format nil "~(~a~)" rate) name)))
    `(progn 
       (defparameter ,name ',var)
       (defparameter ,var ,value)
       (setf *assign-statements* 
                 (cons (format nil "~A = ~A" ,name ,value) *assign-statements*)))))

(defmacro assign* (&rest args)
  `(progn ,@(mapcar (lambda (arg) (cons 'assign arg)) args)))

(defun opcode-call (opcode &rest args)
  (format nil "~a ~{~a~^, ~}" opcode (mapcar (lambda (arg) 
             (if (stringp arg) 
                 (let ((var (gensym)))
                   (eval (list 'assign (symb (symbol-name var)) arg 'a))
                   (symbol-value (symb (symbol-name var)))) 
                 arg)) 
          args)))

(defmacro op (opcode &rest args)
  `(opcode-call ',opcode ,@args))

为了演示代码的作用：

(progn  
  (defparameter *assign-statements* nil)
  (assign* 
    (freq 'p4)
    (amp 'p5)
    (att (+ 0.1 0.1))
    (dec 0.4)
    (sus 0.6)
    (rel 0.7)
    (cutoff 5000)
    (res 0.4 k)
    (env (op madsr (op moogladder freq amp) att dec sus rel) k))
  (format t "~{~A~^~%~}~%" 
      (nreverse *assign-statements*)))

输出：

iFREQ = P4
iAMP = P5
iATT = 0.2
iDEC = 0.4
iSUS = 0.6
iREL = 0.7
iCUTOFF = 5000
kRES = 0.4
aG8707 = MOOGLADDER iFREQ, iAMP
aG8708 = MOOGLADDER iFREQ, iAMP
kENV = MADSR aG8708, iATT, iDEC, iSUS, iREL
NIL

这在所有方面都是正确的，除了“MOOGLADDER iFREQ，iAMP”出现两次。

为什么是这样？我不知道它在哪里被评估了两次。如何消除这种重复？

关于代码的注释：

  • Csound 具有 a、k 和 i 速率变量的概念。这奇怪地实现为变量符号的前缀。lisp 中最接近的对应物是全局变量。所以我已经实现了它。但是为了适应速率，我在符号和它的值之间有一层间接性。例如，符号 'res 的值是 'kRes。现在符号 'kRes 的值是原来的 0.4。

  • 宏 'op 和 'assign* 分别是 'opcode-call 和 'assign 的简单包装。

  • 'opcode-call 是一个函数，因此自动允许正常顺序评估，从而允许嵌套函数调用，csound 本身并不（完全）支持。为了解决这个问题，'opcode-call 通过检查其类型（字符串）在其参数列表中查找任何评估的操作码调用。如果它找到一个字符串，它将用 gensym 变量替换它。

  • 每个 assign 调用都会将分配添加到 assign 语句列表中，然后最终用于输出到 csound 语言。

4

1 回答 1

4

您的宏ASSIGN允许计算两次该值。请参阅下面的评论。

(defmacro assign (_name value &optional (rate 'i))
  (let* ((name (if (typep _name 'symbol) _name (eval _name)))
         (var (symb (format nil "~(~a~)" rate) name)))
    `(progn 
       (defparameter ,name ',var)
       (defparameter ,var ,value)
       (push (format nil "~A = ~A" ,name ,var)    ; <- use the var
             *assign-statements*))))

试试看：

CL-USER 52 > (progn  
               (defparameter *assign-statements* nil)
               (assign* 
                (freq 'p4)
                (amp 'p5)
                (att (+ 0.1 0.1))
                (dec 0.4)
                (sus 0.6)
                (rel 0.7)
                (cutoff 5000)
                (res 0.4 k)
                (env (op madsr (op moogladder freq amp) att dec sus rel) k))
               (format t "~{~A~^~%~}~%" 
                       (nreverse *assign-statements*)))
iFREQ = P4
iAMP = P5
iATT = 0.2
iDEC = 0.4
iSUS = 0.6
iREL = 0.7
iCUTOFF = 5000
kRES = 0.4
aG2719 = MOOGLADDER iFREQ, iAMP
kENV = MADSR aG2719, iATT, iDEC, iSUS, iREL
NIL
于 2017-05-18T14:51:03.653 回答