2

要求：获取输入目录下符合以下条件的目录个数

  1. 目录可以有任何名称，除了“DIR1”、“DIR2”、“DIR3”等。
  2. “DIR1”、“DIR2”、“DIR3”等内的目录不需要计算在内
  3. 只需要目录数量，不需要文件
use strict;
use File::Find;

my ($inputdir) = @ARGV; 
my (@branches, $branch, $directory, @directories); 
my $count = 0; 

find(\&wanted, $inputdir); 
    while ( defined($directory = shift @directories) ) {
          if (-d $directory){ 
             next if ($directory =~ "DIR1" || $directory =~ "DIR2" || $directory =~ "DIR3"); 
                     push @branches, $directory; 
                     $count++; 
          }
    } 

print "Total number of directories: $count \n"; 

sub wanted{
    push @directories, $File::Find::name;
    return @directories; 
}

这段代码提供了所需的输出，但需要花费大量时间。

请提出通过改进此代码来减少时间的方法。

4

1 回答 1

3

File::Find::Rule可以完全跳过整个分支

use warnings;
use strict;

use File::Find::Rule;

my $start_dir = shift || '.';

my $re_skip = qr/DIR(?:1|2|3)/;

my $ok   = File::Find::Rule->directory;  # add selection rules as needed
my $skip = File::Find::Rule->directory
    ->name(qr/$re_skip/)
    ->prune
    ->discard; 

my @dirs = File::Find::Rule -> any($skip, $ok) -> in($start_dir); 

print "Total: ", scalar @dirs, "\n";

对于大型文件系统，这仍然需要一些时间，但它会好得多。

在单线中，如果您需要的只是快速计数

perl -MFile::Find::Rule -wE'
    $ffr = File::Find::Rule; 
    $skip = $ffr->directory->name(qr/DIR(?:1|2|3)/)->prune->discard; 
    say scalar $ffr->any($skip, $ffr->directory)->in(".")'

我已经整合了脚本中的一些代码。

下一步将是使用多线程执行（我会fork在这里使用）。对子目录进行分组，使它们的子数量大致平衡，并在这些组上并行运行类似上述的操作。增益将取决于您的硬件，但应该有一个很好的加速因素。

于 2017-05-16T17:15:41.360 回答