4

从我管理的 oracle 10gR2 10.2.05 数据库中提取 BLOBS 时出现性能问题。我有大约 400 个存储为 BLOBS 的文件，我需要将它们写出到文件系统中。下面是我的代码。当我执行此过程时，前 8 个左右的文件会在几秒钟内写入，然后速度会呈指数级下降，在前 8 个之后每 40 秒大约有 1 个文件。对我来说这没有任何意义，为什么要前 8 个文件很快，但之后一切都变慢了。我尝试将其作为存储过程运行，将 UTL_FILE.fopen 更改为“wb”（写入二进制文件），并使用 NFS 安装的文件系统，以免影响数据库的性能。这些都没有产生任何影响。按照这个速度，我需要 6 个小时来提取 400 个平均每个大约 1.5MB 的文件。有没有人看到我的代码有什么问题或者知道更好的方法来做到这一点？顺便说一句，我使用了这里找到的示例代码http://www.oracle-base.com/articles/9i/ExportBlob9i.php作为起点。

谢谢你的帮助！

DECLARE
  TYPE comment_text IS TABLE OF documents.comment_text%TYPE;
  TYPE localdata IS TABLE OF documents.localdata%TYPE;
  l_file UTL_FILE.FILE_TYPE;
  l_buffer RAW(32767);
  l_amount BINARY_INTEGER := 32767;
  l_pos INTEGER := 1;
  l_blob localdata;
  l_fname comment_text;
  l_blob_len INTEGER;
  l_x NUMBER := 1;
BEGIN
  SELECT comment_text, localdata
  BULK COLLECT INTO l_fname, l_blob
  FROM documents
  WHERE user_id='BILLYBOB';
  IF SQL%ROWCOUNT =0 THEN
    DBMS_OUTPUT.PUT_LINE('No records found!');
  ELSE
    FOR i IN l_fname.FIRST .. l_fname.LAST
    LOOP
      l_blob_len := DBMS_LOB.getlength(l_blob(i));
      DBMS_OUTPUT.PUT_LINE(l_blob_len);
      l_file := UTL_FILE.fopen('BLOBS',l_x || '_' || l_fname(i),'w', 32767);
      l_pos := 1;
      l_x := l_x + 1;
      WHILE l_pos < l_blob_len
      LOOP
        DBMS_LOB.read(l_blob(i), l_amount, l_pos, l_buffer);
        UTL_FILE.put_raw(l_file, l_buffer, TRUE);
        l_pos := l_pos + l_amount;
      END LOOP;
      UTL_FILE.fclose(l_file);
    END LOOP;
  END IF;
END;
4

1 回答 1

1

我很确定您不应该在程序开始时将所有 BLOB 提取到一个数组中。由于您读取了 BLOB 数据并且从未真正关闭任何 lob 定位器，因此 Oracle 必须将所有这些信息保存在内存中。我猜这是内存溢出的情况。

试试这个：

CURSOR cc IS (SELECT ...)
BEGIN
   OPEN cc;
   LOOP
      FETCH cc
         INTO l_fname, l_blob;
      EXIT WHEN cc%NOTFOUND;
      l_blob_len := DBMS_LOB.getlength(l_blob);
      DBMS_OUTPUT.PUT_LINE(l_blob_len);
      l_file := UTL_FILE.fopen('BLOBS', l_x || '_' || l_fname, 'w', 32767);
      l_pos  := 1;
      l_x    := l_x + 1;
      WHILE l_pos < l_blob_len LOOP
         DBMS_LOB.READ(l_blob, l_amount, l_pos, l_buffer);
         UTL_FILE.put_raw(l_file, l_buffer, TRUE);
         l_pos := l_pos + l_amount;
      END LOOP;
      UTL_FILE.fclose(l_file);
   END LOOP;
   CLOSE cc;
END;
于 2010-12-08T22:34:41.227 回答