5

我正在使用 Clojure 规范来规范一个简单的数据结构：

{:max 10
 :data [[3 8 1]
        [9 0 1]]}

该值是在从零到值（含:data）的区间内的等大小整数向量的向量。:max我用规范表达了这一点，如下所示：

(s/def ::max pos-int?)
(s/def ::row (s/coll-of nat-int? :kind vector?, :min-count 1))
(s/def ::data (s/and (s/coll-of ::row :kind vector?, :min-count 1)
                     #(apply = (map count %))))

(s/def ::image (s/and (s/keys :req-un [::max ::data])
                      (fn [{:keys [max data]}]
                        (every? #(<= 0 % max) (flatten data)))))

自动生成器适用于前三个规格，但不适用于::image. (s/exercise ::image)尝试 100 次后总是失败。

我试图创建一个自定义生成器，::image但没有管理。我看不出如何表达跨越嵌套结构层的约束（键:max约束其他地方的向量中的值）。

是否可以创建一个生成 s 的 Clojure spec/test.check 生成器::image？

4

1 回答 1

8

确实！这里的关键是创建域的模型。这里我认为模型是最大、列大小和行大小。这足以生成一个有效的示例。

所以是这样的：

(def image-gen
  (gen/bind
    (s/gen (s/tuple pos-int? (s/int-in 1 8) (s/int-in 1 8)))
    (fn [[max rows cols]]
      (gen/hash-map
        :max (s/gen #{max})
        :data (gen/fmap #(into [] (partition-all cols) %)
                (s/gen (s/coll-of (s/int-in 0 (inc max)) 
                                  :kind vector?
                                  :count (* rows cols))))))))

首先，我们生成一个元组[<max-value> <rows> <cols>]。然后gen/bind返回一个新的生成器，该生成器创建所需形状的地图。我们在内部嵌套gen/fmap以构建所有随机数据值的向量，然后将其重新塑造成适当的嵌套向量形式。

然后，您可以将其组合成图像：

(s/def ::image
  (s/with-gen 
    (s/and (s/keys :req-un [::max ::data])
           (fn [{:keys [max data]}]
             (every? #(<= 0 % max) (flatten data))))
    (fn [] image-gen)))

需要注意的一件可能有趣的事情是，我将行和列限制为不超过 7，因为生成器可能会尝试生成非常大的随机随机样本值。需要绑定这样的东西在自定义生成器中很常见。

通过更多的努力，您还可以从这些规范和生成器中获得更多的重用。

于 2017-05-11T18:46:07.810 回答