0

我有一个小型测试项目，用于从服务器检查应用程序版本并提示用户更新。一切正常，除了我无法保存类型System.Versionto My.Settings。（我想保存新版本，以防用户要求不再提醒它。）

现在，我知道我可以将 Version 保存为字符串并来回转换 - 我已经这样做来解决这个问题 - 但正如System.Version可用设置数据类型中列出的那样，我认为它应该可以工作。但不是保存版本，它只是保存一个没有值的 XML 条目“版本”（参见下文）。

我正在使用 VB.NET、VS 2013、.NET 4。

这是一些要查看的代码：

设置.Designer.vb

<Global.System.Configuration.UserScopedSettingAttribute(),  _
Global.System.Diagnostics.DebuggerNonUserCodeAttribute()>  _
Public Property DoNotRemindVersion() As Global.System.Version
    Get
        Return CType(Me("DoNotRemindVersion"),Global.System.Version)
    End Get
    Set
        Me("DoNotRemindVersion") = value
    End Set
End Property

示例分配

If My.Settings.DoNotRemind Then My.Settings.DoNotRemindVersion = oVersion.NewVersion

（oVersion.NewVersion是类型System.Version。）

保存在 user.config

<setting name="DoNotRemindVersion" serializeAs="Xml">
    <value>
        <Version xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" />
    </value>
</setting>

那么，我做错了什么？我已经阅读了一些关于必须序列化类以将它们保存到用户设置的帖子，但这是一个简单的版本号，从表面上看，我希望它是受支持的数据类型。

4

1 回答 1

2

System.Version 类标有 ，SerializableAttribute但您需要使用SettingsSerializeAsAttribute标记属性并传递System.Configuration.SettingsSerializeAs.Binary值。

您不能使用项目设置设计器界面来自动生成您在Settings.designer.vb文件中找到的代码。您需要自己扩展 My Namespace - MySettings 类。这是部分类有用的领域之一。

将一个新的类文件添加到您的项目中，并命名为 CustomMySettings 之类的创意。选择并删除此新文件中的自动生成代码，并将其替换为以下代码。

Namespace My
    Partial Friend NotInheritable Class MySettings
        ' The trick here is to tell it serialize as binary
        <Global.System.Configuration.SettingsSerializeAs(System.Configuration.SettingsSerializeAs.Binary)> _
        <Global.System.Configuration.UserScopedSettingAttribute(), _
        Global.System.Diagnostics.DebuggerNonUserCodeAttribute()> _
        Public Property DoNotRemindVersion() As Global.System.Version
            Get
                    Return CType(Me("DoNotRemindVersion"), Global.System.Version)
            End Get
            Set(value As Global.System.Version)
                    Me("DoNotRemindVersion") = value
            End Set
        End Property
    End Class
End Namespace

这将允许您My.Settings.DoNotRemindVersion像通过设计器创建设置一样使用。第一次访问该设置时，它将有一个空（无）值，因此您可以在 Form.Load 事件处理程序中使用以下内容对其进行初始化。

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    Dim savedVersion As Version = My.Settings.DoNotRemindVersion
    If savedVersion Is Nothing Then
        My.Settings.DoNotRemindVersion = New Version(1, 0)
        My.Settings.Save()
    End If
End Sub
于 2017-05-10T02:29:34.110 回答