5

我们现在使用 NHibernate 连接到基于我们软件安装位置的不同数据库。所以我将许多 SQL 过程移植到 Oracle。

SQL Server 有一个名为 DateDiff 的好函数，它接受日期部分、开始日期和结束日期。

日期部分示例为日、周、月、年等。.

什么是 Oracle 等价物？

我还没有找到我必须创建自己的版本吗？

（由 Mark Harrison 更新）有几个很好的答案可以解释 Oracle 日期算法。如果您需要 Oracle datediff() 请参阅爱因斯坦的回答。（我需要这个来保持 Sybase 和 Oracle 之间的 spme SQL 脚本兼容。）请注意，这个问题同样适用于 Sybase。

4

4 回答 4

5

几年前我从一篇旧的汤姆文章中窃取了大部分内容，修复了文章中的一些错误并清理了它。datediff 的分界线在 oracle 和 MSSQL 之间的计算方式不同，因此您必须小心一些浮动的示例，这些示例不能正确解释不提供分数结果的 MSSQL/Sybase 样式边界。

通过以下内容，您应该能够使用 MSSQL 语法并获得与 MSSQL 相同的结果，例如 SELECT DATEDIFF(dd,getdate(),DATEADD(dd,5,getdate())) FROM DUAL;

我只声称它有效——而不是它的有效或最好的方法。我不是 Oracle 人 :) 你可能要三思而后行，使用我的函数宏来解决需要 dd、mm、hh、mi..etc 周围的引号。

（由 Mark Harrison 更新）添加 dy 函数作为 dd 的别名。

CREATE OR REPLACE FUNCTION GetDate 
RETURN date IS today date;
BEGIN
RETURN(sysdate);
END;
/

CREATE OR REPLACE FUNCTION mm RETURN VARCHAR2 IS BEGIN RETURN('mm'); END;
/
CREATE OR REPLACE FUNCTION yy RETURN VARCHAR2 IS BEGIN RETURN('yyyy'); END;
/
CREATE OR REPLACE FUNCTION dd RETURN VARCHAR2 IS BEGIN RETURN('dd'); END;
/
CREATE OR REPLACE FUNCTION dy RETURN VARCHAR2 IS BEGIN RETURN('dd'); END;
/
CREATE OR REPLACE FUNCTION hh RETURN VARCHAR2 IS BEGIN RETURN('hh'); END;
/
CREATE OR REPLACE FUNCTION mi RETURN VARCHAR2 IS BEGIN RETURN('mi'); END;
/
CREATE OR REPLACE FUNCTION ss RETURN VARCHAR2 IS BEGIN RETURN('ss'); END;
/

CREATE OR REPLACE Function DateAdd(date_type IN varchar2, offset IN integer, date_in IN date )
RETURN date IS date_returned date;
BEGIN
date_returned := CASE date_type
    WHEN 'mm'   THEN add_months(date_in,TRUNC(offset))
    WHEN 'yyyy' THEN add_months(date_in,TRUNC(offset) * 12)
    WHEN 'dd'   THEN date_in + TRUNC(offset)
    WHEN 'hh'   THEN date_in + (TRUNC(offset) / 24)
    WHEN 'mi'   THEN date_in + (TRUNC(offset) /24/60)
    WHEN 'ss'   THEN date_in + (TRUNC(offset) /24/60/60)
    END;
RETURN(date_returned);
END;
/

CREATE OR REPLACE Function DateDiff( return_type IN varchar2, date_1 IN date, date_2 IN date)
RETURN integer IS number_return integer;
BEGIN
number_return := CASE return_type
    WHEN 'mm'   THEN ROUND(MONTHS_BETWEEN(TRUNC(date_2,'MM'),TRUNC(date_1, 'MM')))
    WHEN 'yyyy' THEN ROUND(MONTHS_BETWEEN(TRUNC(date_2,'YYYY'), TRUNC(date_1, 'YYYY')))/12
    WHEN 'dd'   THEN ROUND((TRUNC(date_2,'DD') - TRUNC(date_1, 'DD')))
    WHEN 'hh'   THEN (TRUNC(date_2,'HH') - TRUNC(date_1,'HH')) * 24
    WHEN 'mi'   THEN (TRUNC(date_2,'MI') - TRUNC(date_1,'MI')) * 24 * 60
    WHEN 'ss'   THEN (date_2 - date_1) * 24 * 60 * 60
    END;
RETURN(number_return);
END;
/
于 2008-11-23T21:35:47.083 回答
4

JohnLavoie - 你不需要那个。Oracle 中的 DATE 实际上是一种日期和时间数据类型。DATE 和 TIMESTAMP 之间的唯一区别是 DATE 解析到秒，而 TIMESTAMP 解析到微秒。因此，Ask Tom 文章也完全适用于 TIMESTAMP 列。

于 2008-09-07T09:58:55.523 回答
1

汤姆的文章很老了。它只讨论 DATE 类型。如果您使用 TIMESTAMP 类型，则日期算术内置于 PL/SQL 中。

http://www.akadia.com/services/ora_date_time.html

DECLARE
ts_a timestamp;
ts_b timestamp;
diff interval day to second;
BEGIN
  ts_a := systimestamp;
  ts_b := systimestamp-1/24;
  diff := ts_a - ts_b;
  dbms_output.put_line(diff);
END;
+00 01:00:00.462000

或者

DECLARE
ts_b timestamp;
ts_a timestamp;
date_part interval day to second;

BEGIN
  ts_a := systimestamp;
  date_part := to_dsinterval('0 01:23:45.678');
  ts_b := ts_a + date_part;
  dbms_output.put_line(ts_b);
END;

04-SEP-08 05.00.38.108000 PM
于 2008-09-04T19:38:23.067 回答
0

您可以为此在 oracle 中编写一个函数

function        datediff( p_what in varchar2, p_d1 in date, p_d2 in date) return number as  l_result    number; 
BEGIN
      select (p_d2-p_d1) * 
             decode( upper(p_what), 'SS', 24*60*60, 'MI', 24*60, 'HH', 24, NULL ) 
       into l_result from dual; 

      return l_result; 
END;

并像这样使用它：

DATEDIFF('YYYY-MM-DD', SYSTIMESTAMP, SYSTIMESTAMP)
于 2014-10-20T12:29:29.843 回答