3

我知道 Cx 1，它将在水平和垂直方向上最大化当前窗口。

但是，我的问题是，是否可以仅在一个方向上将当前窗口扩展到框架边缘？

因此，在下面我想将窗口 A 扩展到框架的右边框，占用 B 和 C 当前占用的空间。但我希望 D 和 E 保持不变......而且我想在单个命令。

请原谅对 ASCII 艺术的可怕尝试！

 _______________________
| AAAAAA |BBBBBB |CCCC  |
|________|_______|______|
| DDDDD  | EEEEEEEEEE   |
|________|______________|

我知道您一次可以水平移动 1 个字符，并且您可以使用重复 n 次命令多次执行此操作，但两者都很笨重，当我真正想说的是扩展到右侧边界时，我不不在乎那有多远。

最接近我想出这个去占据你想要的空间并调用 CX 0 的每一帧，但这仍然有点笨拙。

我需要它在终端模式（emacs -nw）而不是图形/X-Windows 模式下工作。

有任何想法吗？

4

2 回答 2

2

您可以使用库frame-cmds.el（描述）来做到这一点。

它提供了这些命令：

  • maximize-frame-horizontally, maximize-frame-vertically, 和max-frame
  • restore-frame-horizontally, restore-frame-vertically, 和restore-frame

“恢复”命令实际上是在最大化和恢复之间交替的切换。（它们是 commands 的别名toggle-max-frame*。）

命令maximize-frame和restore-frame是通用的，并且可以通过给它们一个前缀 arg 来像水平和垂直命令一样发挥作用：水平的负数，垂直的非负数。

于 2017-05-04T23:19:54.843 回答
0

我有同样的问题：我想水平而不是垂直最大化一个窗口。在网上搜索无济于事后，我决定编写自己的函数。我想在这里分享它，以防将来对某人有所帮助。

(require 'cl-lib)
(defun durand-maximize-window-horizontally (&optional window)
  "Make WINDOW have the same width as the frame.
WINDOW defaults to the selected window.
Other windows are retained, but moved to the top."
  (let* ((window (or window (selected-window)))
         ;; the list of windows to the left
         (left-windows-list (let ((temp-window window)
                                  window-list)
                              (cl-loop while (window-in-direction
                                              'left temp-window t)
                                       do (let ((left-win
                                                 (window-in-direction
                                                  'left temp-window t)))
                                            (push left-win window-list)
                                            (setf temp-window left-win)))
                              window-list))
         ;; the list of windows to the right
         (right-windows-list (let ((temp-window window)
                                   window-list)
                               (cl-loop while (window-in-direction
                                               'right temp-window t)
                                        do (let ((right-win
                                                  (window-in-direction
                                                   'right temp-window t)))
                                             (setf window-list
                                                   (append window-list
                                                           (list right-win)))
                                             (setf temp-window right-win)))
                               window-list))
         ;; the list of windows to the left and to the right
         ;; the order is from left to the right.
         (same-level-list (append left-windows-list right-windows-list))
         ;; save all parameters: the car is the buffer, and the cadr is a list
         ;; of parameters.
         (window-parameters-list
          (cl-loop for win in same-level-list
                   collect (list (window-buffer win)
                                 ;; (window-width win)
                                 (window-parameters win)))))
    (cl-loop for win in same-level-list
             do (delete-window win))
    ;; now our window is the only window horizontally speaking.
    ;; now we shall create them once again, if they exist.
    (when same-level-list
      (let* ((split-base-window
              (split-window window nil 'above))
             (new-windows (list split-base-window))
             newly-created-window)
        (cl-loop
         for ind from 1 to (1- (length same-level-list))
         do
         (setf newly-created-window
               (split-window split-base-window
                             nil 'right)
               ;; NOTE: it is important this list also follows the order
               ;; of going from the left to the right
               new-windows (append new-windows
                                   (list newly-created-window))
               split-base-window newly-created-window))
        (cl-loop for index from 0 to (1- (length same-level-list))
                 do
                 (let ((buf (car (nth index window-parameters-list)))
                       (paras (cadr (nth index window-parameters-list))))
                   (set-window-buffer
                    (nth index new-windows) buf)
                   (cl-loop for para-pair in paras
                            do (set-window-parameter
                                (nth index new-windows)
                                (car para-pair)
                                (cdr para-pair)))))))))
于 2020-04-23T15:11:38.010 回答