8

我遇到了匹配 OCR 识别文本中的字符串并找到它的位置的问题，考虑到可以任意容忍错误、缺失或额外的字符。结果应该是最佳匹配位置，可能（不一定）具有匹配子字符串的长度。

例如：

String: 9912, 1.What is your name?
Substring: 1. What is your name?
Tolerance: 1
Result: match on character 7

String: Where is our caat if any?
Substring: your cat
Tolerance: 2
Result: match on character 10

String: Tolerance is t0o h1gh.
Substring: Tolerance is too high;
Tolerance: 1
Result: no match

我试图调整 Levenstein 算法，但它不适用于子字符串并且不返回位置。

Delphi 中的算法将是首选，但任何实现或伪逻辑都可以。

4

2 回答 2

8

这是一个可行的递归实现，但可能不够快。最坏的情况是找不到匹配项，并且除了“What”中的最后一个字符之外的所有字符都在 Where 中的每个索引处匹配。在这种情况下，算法将对 Where 中的每个字符进行 Length(What)-1 + Tolerance 比较，加上每个 Tolerance 一个递归调用。由于公差和 What are constnats 的长度，我会说算法是 O(n)。它的性能会随着“What”和“Where”的长度线性下降。

function BrouteFindFirst(What, Where:string; Tolerance:Integer; out AtIndex, OfLength:Integer):Boolean;
  var i:Integer;
      aLen:Integer;
      WhatLen, WhereLen:Integer;

    function BrouteCompare(wherePos, whatPos, Tolerance:Integer; out Len:Integer):Boolean;
    var aLen:Integer;
        aRecursiveLen:Integer;
    begin
      // Skip perfect match characters
      aLen := 0;
      while (whatPos <= WhatLen) and (wherePos <= WhereLen) and (What[whatPos] = Where[wherePos]) do
      begin
        Inc(aLen);
        Inc(wherePos);
        Inc(whatPos);
      end;
      // Did we find a match?
      if (whatPos > WhatLen) then
        begin
          Result := True;
          Len := aLen;
        end
      else if Tolerance = 0 then
        Result := False // No match and no more "wild cards"
      else
        begin
          // We'll make an recursive call to BrouteCompare, allowing for some tolerance in the string
          // matching algorithm.
          Dec(Tolerance); // use up one "wildcard"
          Inc(whatPos); // consider the current char matched
          if BrouteCompare(wherePos, whatPos, Tolerance, aRecursiveLen) then
            begin
              Len := aLen + aRecursiveLen;
              Result := True;
            end
          else if BrouteCompare(wherePos + 1, whatPos, Tolerance, aRecursiveLen) then
            begin
              Len := aLen + aRecursiveLen;
              Result := True;
            end
          else
            Result := False; // no luck!
        end;
    end;

  begin

    WhatLen := Length(What);
    WhereLen := Length(Where);

    for i:=1 to Length(Where) do
    begin
      if BrouteCompare(i, 1, Tolerance, aLen) then
      begin
        AtIndex := i;
        OfLength := aLen;
        Result := True;
        Exit;
      end;
    end;

    // No match found!
    Result := False;

  end;

我使用以下代码来测试该功能：

procedure TForm18.Button1Click(Sender: TObject);
var AtIndex, OfLength:Integer;
begin
  if BrouteFindFirst(Edit2.Text, Edit1.Text, ComboBox1.ItemIndex, AtIndex, OfLength) then
    Label3.Caption := 'Found @' + IntToStr(AtIndex) + ', of length ' + IntToStr(OfLength)
  else
    Label3.Caption := 'Not found';
end;

对于案例：

String: Where is our caat if any?
Substring: your cat
Tolerance: 2
Result: match on character 10

它显示了长度为 6 的字符 9 的匹配项。对于其他两个示例，它给出了预期的结果。

于 2010-12-07T11:15:29.340 回答
0

这是模糊匹配（近似搜索）的完整示例，您可以根据需要使用/更改算法！ https://github.com/alidehban/FuzzyMatch

于 2020-12-03T23:49:48.527 回答