3

我正在编写一个 FSCheck 生成器来创建具有以下属性的字符串：

  • 它们是非空的
  • 修剪它们不会影响长度
  • 它们不包含空格。

这是我的生成器代码：

namespace Example

open FsCheck.Arb

module public Generation = 

    let hasChars (s : string) =
        (isNull s |> not)
        && s.Length > 0

    let isTrimmed (s : string) =
        s.Trim().Length = s.Length

    let isContinuous (s : string) =
        s
        |> Seq.exists ((=) ' ')
        |> not

    [<AbstractClass; Sealed>]
    type public Generators = class end

    type public ContinuousString = ContinuousString of string with
        member x.Get = match x with ContinuousString r -> r
        override x.ToString() = x.Get

    type public Generators with

        static member ContinuousString() =
            Default.String()
            |> filter hasChars
            |> filter isTrimmed
            |> filter isContinuous
            |> convert ContinuousString string

这是一个旨在验证生成的测试：

[<Property(Arbitrary=[| typeof<ContinuousString> |], MaxTest=2)>]
let ``A continuous string contains no spaces`` (s: ContinuousString) =
    s.Get.Contains " " |> not

当我运行这个测试时，我得到：

System.Exception: No instances found on type Example.Generation+ContinuousString. Check that the type is public and has public static members with the right signature.

据我所知，查看 FSCheck 源代码，我定义的成员应该由发现过滤器找到，并且该方法似乎类似于类似的内置方法，例如NonEmptyString.

我错过了什么？谢谢！

4

1 回答 1

5

您传递的 FsCheck 类型错误。你应该通过你的Generators课程，而不是你的ContinuousStringDU。即，这个：

[<Property(Arbitrary=[| typeof<ContinuousString> |], MaxTest=2)>]
let ``A continuous string contains no spaces`` (s: ContinuousString) =
    s.Get.Contains " " |> not

本来应该：

[<Property(Arbitrary=[| typeof<Generators> |], MaxTest=2)>]
let ``A continuous string contains no spaces`` (s: ContinuousString) =
    s.Get.Contains " " |> not

FsCheck 错误消息也试图告诉您这一点：

检查该类型是否是公共的并且具有具有正确签名的公共静态成员。

您创建的与它正在寻找的类型相匹配的类型是Generators.

于 2017-04-17T15:45:34.180 回答