15

在 Quick Controls 2.0 应用程序中使用 TableView 可以吗？这将需要两个导入：

import QtQuick.Controls 1.4
import QtQuick.Controls 2.0

我会得到任何副作用吗？

另一个相关问题：TableView 似乎属于 Quick Controls 1.0 集。是吗？这是否意味着如果可以使用 TableView 那么就可以在 Quick Controls 2.0 应用程序中使用所有 Quick Controls 1.0 控件？

4

2 回答 2

21

虽然可以在同一个应用程序中混合使用 Qt Quick Controls 1 和 2，但最大的问题是 Qt Quick Controls 1 与 Qt 的自动高 DPI 缩放不兼容，而 Qt Quick Controls 2 的可扩展性基于此。因此，在高 DPI 显示器上运行混合两者的应用程序可能不会产生理想的结果。

鉴于 Qt Quick Controls 1TableView存在严重的性能问题，一种可能的替代方法是使用ListView来自 Qt Quick 核心的纯文本Row作为委托。使用 Qt 5.9 及更高版本，可以显式指定内容宽度和滑动方向，以便垂直ListView也可以水平滑动。这是一个过于简单的多列列表示例，您已经可以使用最新的 Qt 5.9 beta 进行尝试：

import QtQuick 2.9
import QtQuick.Controls 2.2

ApplicationWindow {
    id: window
    width: 360
    height: 360
    visible: true

    ListView {
        id: listView
        anchors.fill: parent

        contentWidth: headerItem.width
        flickableDirection: Flickable.HorizontalAndVerticalFlick

        header: Row {
            spacing: 1
            function itemAt(index) { return repeater.itemAt(index) }
            Repeater {
                id: repeater
                model: ["Quisque", "Posuere", "Curabitur", "Vehicula", "Proin"]
                Label {
                    text: modelData
                    font.bold: true
                    font.pixelSize: 20
                    padding: 10
                    background: Rectangle { color: "silver" }
                }
            }
        }

        model: 100
        delegate: Column {
            id: delegate
            property int row: index
            Row {
                spacing: 1
                Repeater {
                    model: 5
                    ItemDelegate {
                        property int column: index
                        text: qsTr("%1x%2").arg(delegate.row).arg(column)
                        width: listView.headerItem.itemAt(column).width
                    }
                }
            }
            Rectangle {
                color: "silver"
                width: parent.width
                height: 1
            }
        }

        ScrollIndicator.horizontal: ScrollIndicator { }
        ScrollIndicator.vertical: ScrollIndicator { }
    }
}

TableView当然，这种简化的多列列表不提供诸如可移动和可调整大小的列以及内置在良好旧类型中的其他花里胡哨的功能。另一方面，性能处于完全不同的水平，因此，如果您的目标不是在具有无限资源的计算机上运行的经典桌面环境，那么这条路线可能值得考虑。;)

于 2017-05-08T19:39:05.373 回答
13 
import QtQuick.Controls 1.4 as C
import QtQuick.Controls 2.0

C.TableView {  //controls 1.4
   Button {  //controls 2.0
   }
}

这将帮助您避免两个控件之间发生任何不必要的冲突

于 2017-11-07T00:17:49.970 回答