class - Inno Setup 在事件处理程序中获取 TObject 类型/类

Question

我有一个事件过程，用于检查两个对象/控件（和）的OnKeyUp按键。两个对象都需要在启用之前完成。TNewEditTNewComboBoxTNewButton

但是，我找不到一种方法来知道如何获取 的类型Sender: TObject，如果那是TNewEditor TNewComboBox。

任何人都可以帮忙吗？

Answer 1

您不需要知道任何东西的类型/类。

这种需求是糟糕设计的标志。

---

如果每个类型/类的事件处理不同，请为每个类型/类创建单独的处理程序。

如果部分处理是公用的，则从特定处理程序中调用公用处理程序。

var
  Edit: TNewEdit;
  ComboBox: TNewComboBox;

procedure CommonKeyUp(Sender: TObject; var Key: Word; Shift: TShiftState);  
begin
  Log('Common handling');
end;

procedure EditKeyUp(Sender: TObject; var Key: Word; Shift: TShiftState);
begin
  Log('Edit key up');
  CommonKeyUp(Sender, Key, Shift);
end;

procedure ComboBoxKeyUp(Sender: TObject; var Key: Word; Shift: TShiftState);
begin
  Log('Combo box key up');
  CommonKeyUp(Sender, Key, Shift);
end;

procedure InitializeWizard();
begin
  { ... }

  Edit.OnKeyUp := @EditKeyUp;
  Combobox.OnKeyUp := @ComboBoxKeyUp;
end;

---

尽管您实际上有两个控件，但您可能想区分是哪个控件引发了事件。

也就是说，Sender争论的目的是什么。下面的代码展示了如何使用它。但是，总的来说，这不是正确的方法。

var
  Edit: TNewEdit;
  ComboBox: TNewComboBox;

procedure ControlKeyUp(Sender: TObject; var Key: Word; Shift: TShiftState);
begin
  if Sender = Edit then
  begin
    Log('Edit key up');
  end
    else
  if Sender = ComboBox then
  begin
    Log('Combo box key up');
  end
    else
  begin
    Log('Other key up');
  end;
end;

procedure InitializeWizard();
begin
  { ... }

  Edit.OnKeyUp := @ControlKeyUp;
  Combobox.OnKeyUp := @ControlKeyUp;
end;

---

虽然我还是不明白，你需要这个做什么。

您每次都必须检查这两个控件，那么为什么您需要知道，哪个控件发生了变化？

另外，要检测更改，请不要使用OnKeyUp，请使用OnChange。这样您就可以捕获所有更改（按键、拖放、复制和粘贴等）。

var
  Edit: TNewEdit;
  ComboBox: TNewComboBox;
  Button: TNewButton;

procedure ControlChange(Sender: TObject);
begin
  Button.Enabled := (Edit.Text <> '') and (ComboBox.Text <> '');
end;

procedure InitializeWizard();
begin
  { ... }

  Edit.OnChange := @ControlChange;
  Combobox.OnChange := @ControlChange;
end;