0

Q1 1996我有一个宽格式的数据集，其中包含从到的事件的季度计数Q4 2016。

每个季度的变量名称如下：

  • Q1 =yyyy0101_yyyy0401
  • Q2 =yyyy0401_yyyy0701
  • Q3 =yyyy0701_yyyy1001
  • Q4 =yyyy1001_yyyy0101

我有一个宏可以像这样转换它们：

local i = 1996

forvalues x = 1996/2016 { 
    local i = `i'+1
    gen count`x' = event_`x'0101_`x'0401 + event_`x'0401_`x'0701 + 
    event_`x'0701_`x'1001 + event_`x'1001_`i'0101
}

然后我count按年份将数据折叠成一个长格式的单个变量：

reshape long count, i(xvars) j(year)

现在我想做同样的事情，但每季度一次。

执行完全相同的过程但按年逐季捕获计数总和的宏是什么？如果我想做半年怎么办？

4

1 回答 1

0

在试图理解这一点时，我首先（迂腐地或以其他方式）注意到您的代码不是 Stata 意义上的宏：SAS 用户？？？）其次（更具建设性）您的代码可以压缩为

forvalues x = 1996/2016 { 
    gen count`x' = event_`x'0101_`x'0401 + event_`x'0401_`x'0701 + event_`x'0701_`x'1001 + event_`x'1001_`x'0101
}

鉴于本地宏i并x运行相同的值。（这些是Stata 意义上的宏。）但我不会从那里开始。

正如您所说，数据是宽格式（我更喜欢术语布局，因为它的重载较少），所以主要工作根本不是写循环，而是写reshape长。这个例子体现了一些猜测并展示了一些技巧。由于没有可使用的数据示例，我首先创建了一个沙箱：

clear 
set obs 21
local y = 1 
foreach v in yyyy0101_yyyy0401 yyyy0401_yyyy0701 yyyy0701_yyyy1001 yyyy1001_yyyy0101 { 
    gen `v' = `++y' 
}
gen year = 1995 + _n 

rename (yyyy*) (count#), addnumber 

reshape long count, i(year) j(quarter) 

gen qdate = yq(y, q) 

egen ycount = total(count), by(year) 
egen qcount = total(count), by(quarter) 
gen half = cond(inlist(quarter, 1, 2), 1, 2)
egen hcount = total(count), by(year half) 

list if year < 1998, sepby(year) 

     +------------------------------------------------------------------+
     | year   quarter   count   qdate   ycount   qcount   half   hcount |
     |------------------------------------------------------------------|
  1. | 1996         1       2     144       14       42      1        5 |
  2. | 1996         2       3     145       14       63      1        5 |
  3. | 1996         3       4     146       14       84      2        9 |
  4. | 1996         4       5     147       14      105      2        9 |
     |------------------------------------------------------------------|
  5. | 1997         1       2     148       14       42      1        5 |
  6. | 1997         2       3     149       14       63      1        5 |
  7. | 1997         3       4     150       14       84      2        9 |
  8. | 1997         4       5     151       14      105      2        9 |
     +------------------------------------------------------------------+

正如您已经使用的那样，这与您所做的有什么不同reshape long？主要是强调可以在适当的位置生成您想要的不同时间尺度上的任何总计。您不需要collapse相同数据集的重复或不同版本。如何制表、列出或以其他方式处理重复将是不同的问题。

于 2017-04-10T12:03:22.983 回答