4

作为 meck 的新手，我一直在整理一个测试来显示各种功能。但是，我无法理解为什么开发人员可能会调用 meck:validate。这是我的例子：

-module(meck_demo).

-include_lib("eunit/include/eunit.hrl").

validate_is_of_limited_use_test_() ->
    { foreach, fun setup_mock/0, fun cleanup_mock/1, 
      [fun validate_does_not_fail_if_a_function_is_not_called/0,
       fun validate_does_not_fail_if_a_function_is_called_with_wrong_arity/0,
       fun validate_does_not_fail_if_an_undefined_function_is_called/0,
       fun validate_does_fail_if_a_function_was_called_with_wrong_argument_types/0,
       fun validate_does_fail_if_expectation_throws_an_unexpected_exception/0 ]}.

validate_does_not_fail_if_a_function_is_not_called() ->
    meck:expect(womble, name, fun() -> "Wellington" end),   
    ?assert(meck:validate(womble)).

validate_does_not_fail_if_a_function_is_called_with_wrong_arity() ->
    meck:expect(womble, name, fun() -> "Madame Cholet" end),
    ?assertError(undef, womble:name(unexpected_arg)),
    ?assert(meck:validate(womble)).

validate_does_not_fail_if_an_undefined_function_is_called() ->
    ?assertError(undef, womble:fly()),
    ?assert(meck:validate(womble)).

validate_does_fail_if_a_function_was_called_with_wrong_argument_types() ->
    meck:expect(womble, jump, fun(Height) when Height < 1 -> 
                                ok
                              end),
    ?assertError(function_clause, womble:jump(999)),
    ?assertNot(meck:validate(womble)).

validate_does_fail_if_expectation_throws_an_unexpected_exception() ->
    meck:expect(womble, jump, fun(Height) -> 42 = Height end),
    ?assertError({badmatch, 999}, womble:jump(999)),
    ?assertNot(meck:validate(womble)).   

setup_mock() ->
    meck:new(womble, [non_strict]).

cleanup_mock(_SetupResult) ->
    meck:unload(womble).

我错过了什么？

-- 更新以反映亚当解释的可以被抓住的案例

4

1 回答 1

4

您设法解决了 validate 未涵盖的几乎所有案例（在10c5063中添加了更好的文档）。

验证可以检测：

  • 当使用错误的参数类型调用函数时 ( function_clause)
  • 抛出异常时
  • 当一个异常被抛出和预期时（通过meck:exception/2），这仍然会导致true从meck:validate/1

验证无法检测到：

  • 当你没有调用函数时
  • 当您使用错误数量的参数调用函数时
  • 如果你调用了一个未定义的函数

它无法检测到这些情况的原因是 Meck 的实现方式。Meck 用一个 mock 和一个维护 mock 的进程替换了模块。Meck 得到的一切都通过那个模拟模块。Meck 不会在调用者级别（即在您的模块或测试用例中）插入自己，因此它无法知道您未能调用模块。上面测试用例中的所有失败都不会首先到达模拟模块。

于 2017-04-07T14:21:54.593 回答