2

在Practical Common Lisp的第 8 章末尾，Peter Seibel 介绍了once-only宏。其目的是减轻用户定义的宏中变量评估的一些微妙问题。请注意，此时我并不想理解这个宏是如何工作的，就像在其他一些帖子中一样，而是如何正确使用它：

(defmacro once-only ((&rest names) &body body)
  (let ((gensyms (loop for n in names collect (gensym))))
    `(let (,@(loop for g in gensyms collect `(,g (gensym))))
      `(let (,,@(loop for g in gensyms for n in names collect ``(,,g ,,n)))
        ,(let (,@(loop for n in names for g in gensyms collect `(,n ,g)))
           ,@body)))))

以下是一个示例（不正确）人为的宏，它试图展示几个变量评估问题。它声称通过一些增量迭代整数范围，返回范围：

(defmacro do-range ((var start stop delta) &body body)
  "Sample macro with faulty variable evaluations."
  `(do ((,var ,start (+ ,var ,delta))
        (limit ,stop))
       ((> ,var limit) (- ,stop ,start))
     ,@body))

例如，(do-range (i 1 15 3) (format t "~A " i))应该打印1 4 7 10 13然后返回14。

问题包括 1) 第二次出现的潜在捕获limit，因为它作为自由变量出现，2) 绑定变量的初始出现的潜在捕获limit，因为它与出现在宏参数中的其他变量一起出现在表达式中， 3) 无序评估，sincedelta将在 之前评估stop，即使stop出现delta在参数列表中，以及 4) 多个变量评估，sincestop和start被评估不止一次。据我了解，once-only应该解决这些问题：

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta limit)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
       ,@body)))

但是，(macroexpand '(do-range (i 1 15 3) (format t "~A " i)))抱怨limit是一个未绑定的变量。如果我改用with-gensyms，它应该只处理上面的问题 1 和 2，扩展会顺利进行。

这是once-only宏的问题吗？是否once-only真的解决了上面列出的所有问题（也许还有其他问题）？

4

1 回答 1

5

ONCE-ONLY 宏

为了摆脱N未使用的警告，我会将宏更改为：

(defmacro once-only ((&rest names) &body body)
  (let ((gensyms (loop for nil in names collect (gensym))))
                           ; changed N to NIL, NIL is ignored
    `(let (,@(loop for g in gensyms collect `(,g (gensym))))
      `(let (,,@(loop for g in gensyms for n in names collect ``(,,g ,,n)))
        ,(let (,@(loop for n in names for g in gensyms collect `(,n ,g)))
           ,@body)))))

此宏的目的是确保表达式仅按定义的顺序计算一次。为此，它将引入新的非内部变量并将评估结果绑定到这些变量。在宏内部，新变量可用。提供宏本身是为了使编写宏更容易。

在 DO-RANGE 中使用 ONCE-ONLY

您的示例使用ONCE-ONLY：

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta limit)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
         ,@body)))

为什么LIMIT在once-only列表中？limit在那里未定义。LIMIT在ONCE-ONLY表单内部用作符号，但在外部没有约束力。

ONCE-ONLY期望名称列表是符号列表，并且这些名称绑定到表单。在你的情况下limit是一个符号，但它是未定义的。

我们需要limit从名称列表中删除：

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
         ,@body)))

现在，该怎么办LIMIT？鉴于once-only提供了名称的绑定，包括 for STOP，我们可以消除该符号LIMIT并将其使用替换为,stop：

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta)
    `(do ((,var ,start (+ ,var ,delta)))
         ((> ,var ,stop) (- ,stop ,start))
       ,@body)))

例子：

CL-USER 137 > (pprint
               (macroexpand
                '(do-range (i 4 10 2)
                   (print i))))

(LET ((#1=#:G2170 4)
      (#3=#:G2171 10)
      (#2=#:G2172 2))
  (DO ((I #1# (+ I #2#)))
      ((> I #3#) (- #3# #1#))
   (PRINT I)))
于 2017-04-04T07:49:13.987 回答