我想在 Excel 2007 中使用 VBA 逐步处理大约 500 张收据，这些收据已转换为一个大型 OneNote 2010 笔记本。每个笔记本选项卡都包含不同的收据。我需要从中获取相关详细信息（收据编号、收据日期、金额、所有行项目数据、税收等），并且我想在 Excel 中使用该数据创建一个工作表。
数据是半结构化的，这意味着一旦我找到“订单号”，我就知道有一个空格字符，然后是订单号。但它可能在不同的线路上，甚至被推倒等等。但没关系。我可以编写 VBA 代码，这不是问题..
我认为它比数据输入更容易，或者比雇用某人手动输入所有这些更便宜......我不想走 OCR 路线，因为我需要我认为我可以从某种办公自动化中获得的准确性Excel 和 OneNote。我只是找不到任何使用 OneNote 2010 的自动化示例（无论是从 OneNote 端还是 Excel 端）。另一个可以指出我正确的方向吗？MSDN 有一个 Office 和 OneNote 的开发人员站点，但我一定是瞎了眼，看不到任何示例甚至对象模型！
MSDN 上的这个 VBA 示例代码可能会对您有所帮助。我检索了所有 OneNote 笔记本的列表。它是为 OneNote 2010 编写的，适用于我的 Office 2010 软件包，但我希望它也适用于 2007。
我已修改示例源以检索所有页面和页面内容。页面内容是 XML，因此您必须对其进行解析。
修改后的 MSDN 示例：
'Add the following references (adjust to our office version):
'
' - Microsoft OneNote 14.0 Object Library
' - Microsoft XML, v6.0
Sub ListOneNotePages()
' Original example is from http://code.msdn.microsoft.com/office/onenote-2010-retrieve-data-023e69c0
' License: Apache 2.0
' Modified to get all pages & content instead of the notebook list
' Connect to OneNote 2010.
' OneNote will be started if it's not running.
Dim oneNote As OneNote14.Application
Set oneNote = New OneNote14.Application
' Get the XML that represents the OneNote pages
Dim oneNotePagesXml As String
' oneNotePagesXml gets filled in with an XML document providing information
' about all OneNote pages.
' You want all the data. Thus you provide an empty string
' for the bstrStartNodeID parameter.
oneNote.GetHierarchy "", OneNote14.HierarchyScope.hsPages, oneNotePagesXml, xs2010
' Use the MSXML Library to parse the XML.
Dim doc As MSXML2.DOMDocument
Set doc = New MSXML2.DOMDocument
If doc.LoadXML(oneNotePagesXml) Then
' Find all the Page nodes in the one namespace.
Dim nodes As MSXML2.IXMLDOMNodeList
Set nodes = doc.DocumentElement.SelectNodes("//one:Page")
Dim node As MSXML2.IXMLDOMNode
Dim pageName As String
Dim sectionName As String
Dim pageContent As String
Dim temp As String
' Walk the collection of Pages.
' Read attribute values and write them
' out to the Immediate window of your VBA host.
For Each node In nodes
pageName = node.Attributes.getNamedItem("name").Text
Debug.Print "Page name: "; vbCrLf & " " & pageName
Call oneNote.GetPageContent(GetAttributeValueFromNode(node, "ID"), pageContent, piBasic)
Debug.Print " content: " & pageContent
Next
Else
MsgBox "OneNote 2010 XML Data failed to load."
End If
End Sub
Private Function GetAttributeValueFromNode(node As MSXML2.IXMLDOMNode, attributeName As String) As String
If node.Attributes.getNamedItem(attributeName) Is Nothing Then
GetAttributeValueFromNode = "Not found."
Else
GetAttributeValueFromNode = node.Attributes.getNamedItem(attributeName).Text
End If
End Function
我不知道有什么很好的资源可以做你想做的事，但以下两篇文章有一些信息可以帮助你入门：
使用 OneNote 对象模型创建 OneNote 2010 扩展
OneNote 2007 中的开发人员新增功能（第 1 部分，共 2 部分）
要查找更多信息，我建议您在谷歌上搜索Microsoft.Office.Interop.OneNote，希望您能从 .Net 中获得很多关于这样做的问题，即使它可能并不理想，至少可能会给您一些提示。
我找到了一个更好的 VBA 示例，标题为“在 OneNote 2010 中以编程方式搜索”：
Sub SearchTermsInTheFirstNoteBook()
' Connect to OneNote 2010
' OneNote will be started if it's not running.
Dim oneNote As OneNote14.Application
Set oneNote = New OneNote14.Application
' Get all of the Notebook nodes.
Dim nodes As MSXML2.IXMLDOMNodeList
Set nodes = GetFirstOneNoteNotebookNodes(oneNote)
If Not nodes Is Nothing Then
' Get the first notebook found.
Dim node As MSXML2.IXMLDOMNode
Set node = nodes(0)
' Get the ID.
Dim notebookID As String
notebookID = node.Attributes.getNamedItem("ID").Text
' Ask the user for a string for which to search
' with a default search string of "Microsoft".
Dim searchString As String
searchString = InputBox$("Enter a search string.", "Search", "Microsoft")
Dim searchResultsAsXml As String
' The FindPages method search a OneNote object (in this example, the first
' open Notebook). You provide the search string and the results are
' provided as an XML document listing the objects where the search
' string is found. You can control whether OneNote searches non-indexed data (this
' example passes False). You can also choose whether OneNote enables
' the User Interface to show the found items (this example passes False).
' This example instructs OneNote to return the XML data in the 2010 schema format.
oneNote.FindPages notebookID, searchString, searchResultsAsXml, False, False, xs2010
' Output the returned XML to the Immediate Window.
' If no search items are found, the XML contains the
' XML hierarchy data for the searched item.
Debug.Print searchResultsAsXml
Else
MsgBox "OneNote 2010 XML data failed to load."
End If
End Sub
Private Function GetAttributeValueFromNode(node As MSXML2.IXMLDOMNode, attributeName As String) As String
If node.Attributes.getNamedItem(attributeName) Is Nothing Then
GetAttributeValueFromNode = "Not found."
Else
GetAttributeValueFromNode = node.Attributes.getNamedItem(attributeName).Text
End If
End Function
Private Function GetFirstOneNoteNotebookNodes(oneNote As OneNote14.Application) As MSXML2.IXMLDOMNodeList
' Get the XML that represents the OneNote notebooks available.
Dim notebookXml As String
' Fill notebookXml with an XML document providing information
' about available OneNote notebooks.
' To get all the data, provide an empty string
' for the bstrStartNodeID parameter.
oneNote.GetHierarchy "", hsNotebooks, notebookXml, xs2010
' Use the MSXML Library to parse the XML.
Dim doc As MSXML2.DOMDocument
Set doc = New MSXML2.DOMDocument
If doc.LoadXML(notebookXml) Then
Set GetFirstOneNoteNotebookNodes = doc.DocumentElement.SelectNodes("//one:Notebook")
Else
Set GetFirstOneNoteNotebookNodes = Nothing
End If
End Function
它会生成包含 XML 数据的“searchResultsAsXml”，其中列出了存在“searchString”的所有页面；购买指定 TRUE 作为第 5 个参数
oneNote.FindPages notebookID, searchString, searchResultsAsXml, False, False, xs2010
你可以让 OneNote 突出显示结果。
经过对 VBA 和 OneNote 的长期研究，我得出了这个解决方案：
'Add the following references (adjust to our office version):
'
' - Microsoft OneNote 14.0 Object Library
' - Microsoft XML, v6.0
Sub SearchStringInOneNote()
' Original example is from http://code.msdn.microsoft.com/office/onenote-2010-retrieve-data-023e69c0
' License: Apache 2.0
' Modified to get all pages & content instead of the notebook list
StringToSearch = InputBox("Text to search:", "Search in OneNote")
StringToSearch = UCase(StringToSearch) ' Case insensitiveness
' Connect to OneNote 2010.
' OneNote will be started if it's not running.
Dim oneNote As OneNote14.Application
Set oneNote = New OneNote14.Application
' Get the XML that represents the OneNote pages
Dim oneNotePagesXml As String
' oneNotePagesXml gets filled in with an XML document providing information
' about all OneNote pages.
' You want all the data. Thus you provide an empty string
' for the bstrStartNodeID parameter.
oneNote.GetHierarchy "", OneNote14.HierarchyScope.hsPages, oneNotePagesXml, xs2010
' Use the MSXML Library to parse the XML.
Dim doc As MSXML2.DOMDocument
Dim notebooks As MSXML2.IXMLDOMNodeList
Dim sections As MSXML2.IXMLDOMElement
Dim page As MSXML2.IXMLDOMElement
Set doc = New MSXML2.DOMDocument
result = doc.LoadXML(oneNotePagesXml)
Set notebooks = doc.ChildNodes
Set sections = notebooks(1)
For Each section In sections.ChildNodes
Debug.Print "Notebook: "; section.Attributes(1).Text
Set Pages = section.ChildNodes
For Each page In Pages
Debug.Print " Section: " & page.Attributes(0).Text
For Each node In page.ChildNodes
Debug.Print " Page: " & node.Attributes(1).Text
Call ProcessNode(node, oneNote, StringToSearch)
Next
Next
Next
End Sub
Sub ProcessNode(ByVal node As MSXML2.IXMLDOMNode, ByVal oneNote As OneNote14.Application, ByVal StringToSearch As String)
Dim SectionName As String
Dim PageContent As String
Dim pageXML As MSXML2.DOMDocument
Dim TextToSearch As String
Dim TableNode As MSXML2.IXMLDOMNode
Dim RowNode As MSXML2.IXMLDOMNode
Dim Outlines As MSXML2.IXMLDOMNodeList
Dim Tables As MSXML2.IXMLDOMNodeList
' Walk the collection of Pages.
' Read attribute values and write them
' out to the Immediate window of your VBA host.
Call oneNote.GetPageContent(GetAttributeValueFromNode(node, "ID"), PageContent, 4) ' Put page content in XML format into string variable
'---- Put XML page content into XML object:
Set pageXML = New MSXML2.DOMDocument
pageXML.LoadXML (PageContent) ' Load page content in XML format into XML object
pageXML.LoadXML (pageXML.ChildNodes(1).XML) ' Reload same XML object with just significative part of page content (=second node)
Set Outlines = pageXML.DocumentElement.SelectNodes("//one:Outline") ' Store into XML object the collection of outlines of the page
OutlineNumber = 0
TableNumber = 0
For Each Outline In Outlines
OutlineNumber = OutlineNumber + 1
TableNumber = 0
Set TableNode = Outline.ChildNodes(2).ChildNodes(0).ChildNodes(0) 'Outline.SelectNodes("//one:Table").Context 'Outline.SelectNodes("//one:Table").Item(2)
'Debug.Print "Scanning outline n." & OutlineNumber & "..."
If TableNode Is Nothing Then
' If page contains no tables (empty page?)...
Else
ContaRighe = 0
For Each RowNode In TableNode.ChildNodes ' Scan all rows of table
ContaRighe = ContaRighe + 1
If ContaRighe > 1 Then ' Skip first line (contains columns list)
TestoRiga = "" ' Prepare variable to contain all cells of current row
For x = 0 To RowNode.ChildNodes.Length - 1 ' Store all cells text into a variable
TestoRiga = TestoRiga & Chr(9) & RowNode.ChildNodes(x).Text
Next
If InStr(UCase(TestoRiga), StringToSearch) > 0 Then ' Look for string in row.
Debug.Print "FOUND: " & TestoRiga ' Print row if string found
End If
End If
Next
Set TableNode = Nothing
End If ' Table exists
Next ' Outlines
End Sub
Private Function GetAttributeValueFromNode(node As MSXML2.IXMLDOMNode, attributeName As String) As String
If node.Attributes.getNamedItem(attributeName) Is Nothing Then
GetAttributeValueFromNode = "Not found."
Else
GetAttributeValueFromNode = node.Attributes.getNamedItem(attributeName).Text
End If
End Function
不幸的是它很慢......但它有效！
用法：
尽管它很老，但我偶然发现了这个问题，寻找相同的答案（这就是我发现的）：
OneNote 仍然缺少 VBA 编辑器，但是通过名为Onetastic的插件支持宏（不是 VBA） - 请参见此处：https ://www.microsoft.com/en-us/microsoft-365/blog/2013/08/ 01/try-the-onetastic-add-in-to-bring-tons-of-new-features-to-onenote/
似乎 Onetastic 为 OneNote 添加了很多功能，包括它自己的脚本工具 - 请参见此处：https ://getonetastic.com/?r=macros
我知道这不是问题的确切答案，但是...如果对 VBA 的要求有一定的灵活性，这可能会有所帮助。
值得一提的是，当我在笔记本电脑上安装 Onetastic 时，它“正常工作”。当我将它安装在我的桌面上时，它似乎没有做任何事情（即使安装程序报告安装成功）。
我认为不同之处在于笔记本电脑具有 OneNote 365/2016（Windows 10 随附），而台式机具有 OneNote 2010（来自 Office 2010）和 OneNote 365；我怀疑从桌面删除其中一个版本将使一切正常...