0

员工可以是经理、人力资源合作伙伴或两者兼而有之。他们可以是任意数量成本中心的经理。他们可以是任意数量的成本中心的人力资源合作伙伴。

如果我从每条记录中提取我需要的组合，我会收到重复的。员工 A 和员工 B 向同一成本中心的同一经理报告，因此返回两行。一个给员工 A，一个给员工 B。因为我没有提取他们的员工 ID（只有经理和 hr 合作伙伴的），所以它们显示为重复的行。我目前正在使用 '[not(.=preceding::' 来消除重复项，但会检查整个文件，并且只允许经理属于一个成本中心而不是多个成本中心。如何仅对组执行检查（成本中心）而不是整个文件（所有成本中心）？

我尝试了两个复合键（managerID，成本中心 ID）和（hr 合作伙伴，成本中心 ID），但一直在努力解决它，直到它变得混乱并且无法正常工作。不幸的是，我将这段代码保存在上面。因此，如果这真的是我唯一的选择，我将不得不重写它并从那里进行故障排除。

输入 XML 样本：

<wd:Report_Data>
    <wd:Report_Entry>
        <wd:Sub_Employee_ID>123345678</wd:Sub_Employee_ID>
        <wd:Cost_Center_ID>20000003</wd:Cost_Center_ID>
        <wd:HR_Partner>
            <wd:ID wd:type="Employee_ID">81025060</wd:ID>
        </wd:HR_Partner>
        <wd:HR_Partner>
            <wd:ID wd:type="Employee_ID">81452340</wd:ID>
        </wd:HR_Partner>
        <wd:Manager>
            <wd:Employee_ID>81055097</wd:Employee_ID>
        </wd:Manager>
        <wd:Role_ID>2005</wd:Role_ID>
    </wd:Report_Entry>
    <wd:Report_Entry>
        <wd:Sub_Employee_ID>22345123</wd:Sub_Employee_ID>
        <wd:Cost_Center_ID>20000003</wd:Cost_Center_ID>
        <wd:HR_Partner>
            <wd:ID wd:type="Employee_ID">81025060</wd:ID>
        </wd:HR_Partner>
        <wd:Manager>
            <wd:Employee_ID>81055097</wd:Employee_ID>
        </wd:Manager>
        <wd:Role_ID>2005</wd:Role_ID>
    </wd:Report_Entry>
    <wd:Report_Entry>
        <wd:Sub_Employee_ID>33424567</wd:Sub_Employee_ID>
        <wd:Cost_Center_ID>20000003</wd:Cost_Center_ID>
        <wd:HR_Partner>
            <wd:ID wd:type="Employee_ID">81022549</wd:ID>
        </wd:HR_Partner>
        <wd:Manager>
            <wd:Employee_ID>12312312</wd:Employee_ID>
        </wd:Manager>
        <wd:Role_ID>2005</wd:Role_ID>
    </wd:Report_Entry>
    <wd:Report_Entry>
        <wd:Sub_Employee_ID>72390123</wd:Sub_Employee_ID>
        <wd:Cost_Center_ID>40000006</wd:Cost_Center_ID>
        <wd:HR_Partner>
            <wd:ID wd:type="Employee_ID">81025060</wd:ID>
        </wd:HR_Partner>
        <wd:Manager>
            <wd:Employee_ID>81055097</wd:Employee_ID>
        </wd:Manager>
        <wd:Role_ID>2005</wd:Role_ID>
    </wd:Report_Entry>
</wd:Report_Data>

期望的输出：

81055097;
20000003;
2005;
Manager

81025060;
20000003;
2005;
HR Partner

81452340
20000003;
2005;
HR Partner

12312312
20000003;
2005;
Manager

81022549;
20000003;
2005;
HR Partner

81055097;
40000006;
2005;
Manager

81025060;
40000006;
2005;
HR_Partner

当前xslt：

<xsl:template match="wd:Report_Data/wd:Report_Entry">
    <xsl:for-each-group select="." group-by="wd:Cost_Center_ID">

        <!-- Manager Line -->
        <!-- Filter Duplicates -->
        <xsl:sort select="wd:Manager/wd:Employee_ID"/>
        <xsl:if test="wd:Manager/wd:Employee_ID[not(.=preceding::wd:Manager/wd:Employee_ID)]">
            <xsl:value-of select="wd:Manager/wd:Employee_ID"/>;
            <xsl:value-of select="wd:Cost_Center_ID"/>;
            <xsl:value-of select="wd:Role_ID"/>;
            <xsl:value-of>Manager</xsl:value-of>
            <xsl:value-of select="$linefeed"/>
        </xsl:if>

        <!-- HR Partner Line -->
        <!-- Filter Duplicates -->
        <xsl:for-each select="../wd:HR_Partner/wd:ID[@wd:type='Employee_ID']">
            <xsl:if test=".[not(.=preceding::wd:HR_Partner/wd:ID[@wd:type='Employee_ID'])]">
                <xsl:value-of select="wd:ID[@wd:type='Employee_ID']"/>;
                <xsl:value-of select="../wd:Cost_Center_ID"/>;
                <xsl:value-of select="../wd:Role_ID"/>;
                <xsl:value-of>HR Partner</xsl:value-of>
                <xsl:value-of select="$linefeed"/>
            </xsl:if>
        </xsl:for-each> 
    </xsl:for-each-group>
</xsl:template>
4

1 回答 1

1

试试下面给出的解决方案：

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:wd="http://dummy.com"
  xpath-default-namespace="http://dummy.com"
  exclude-result-prefixes="#all">
  <xsl:output method="text" encoding="UTF-8" indent="yes" />
  <xsl:strip-space elements="*"/>

  <xsl:key name="Partners" match="//HR_Partner"
    use="concat(../Cost_Center_ID, '/', ID)"/>
  <xsl:key name="Managers" match="//Manager"
    use="concat(../Cost_Center_ID, '/', Employee_ID)"/>
  <xsl:variable name="lf" select="'&#xA;'"/>

  <xsl:template match="Report_Data">
    <xsl:for-each-group select="Report_Entry" group-by="Cost_Center_ID">
      <xsl:for-each select="current-group()">
        <xsl:sort select="Manager/Employee_ID"/>
        <xsl:for-each select="Manager">
          <xsl:variable name="kk" select="concat(../Cost_Center_ID, '/', Employee_ID)"/>
          <xsl:if test="generate-id()=generate-id(key('Managers', $kk)[1])">
            <xsl:value-of select="Employee_ID"/>
            <xsl:text>; </xsl:text>
            <xsl:value-of select="../Cost_Center_ID"/>
            <xsl:text>; </xsl:text>
            <xsl:value-of select="../Role_ID"/>
            <xsl:text>; Manager;</xsl:text>
            <xsl:value-of select="$lf"/>
          </xsl:if>
        </xsl:for-each>
        <xsl:for-each select="HR_Partner">
          <xsl:variable name="kk" select="concat(../Cost_Center_ID, '/', ID)"/>
          <xsl:if test="generate-id()=generate-id(key('Partners', $kk)[1])">
            <xsl:value-of select="ID"/>
            <xsl:text>; </xsl:text>
            <xsl:value-of select="../Cost_Center_ID"/>
            <xsl:text>; </xsl:text>
            <xsl:value-of select="../Role_ID"/>
            <xsl:text>; HR Partner;</xsl:text>
            <xsl:value-of select="$lf"/>
          </xsl:if>
        </xsl:for-each>
      </xsl:for-each>
    </xsl:for-each-group>
  </xsl:template>
</xsl:transform>

我使用在线 XSLT 验证器对其进行了测试，输入 XML 如下：

<?xml version="1.0" encoding="UTF-8"?>
<wd:main xmlns:wd="http://dummy.com">
  <wd:Report_Data>
  <!-- Here your Report_Entry records -->
  </wd:Report_Data>
</wd:main>

请注意，由于应用了排序，排序顺序与您所需的输出不同。

于 2017-03-28T18:57:06.790 回答