2

我有许多用 xsd 编写的 XML 模式来定义 xml 文档的结构。现在我想用 flatbuffers 替换格式。查看 fbs 格式时，似乎可以使用 XSLT 将 XSD Schema 定义自动转换为 FBS 文件。因为可能还有其他人有同样的问题，所以我在这里问是否已经有一些方法可以解决 XSD Schematas 到 FBS 的自动转换。

XSD 架构示例：

<xs:complexType name="Configuration">
  <xs:sequence>
    <xs:element name="MandatoryDetail" 
                type="ComplexConfigDetail" 
                minOccurs="1" 
                maxOccurs="1"/>
    <xs:element name="OptionalDetail" 
                type="ComplexConfigDetail" 
                minOccurs="0" 
                maxOccurs="1"/>
    <xs:element name="UnboundedDetail" 
                type="ComplexConfigDetail" 
                minOccurs="0" 
                maxOccurs="unbounded"/>
  </xs:sequence>
  <xs:attribute name="MandatoryInt" 
                use="required" 
                type="xs:unsignedInt"/>
  <xs:attribute name="OptionalInt" 
                use="optional" 
                type="xs:unsignedInt"/>
</xs:complexType>

<xs:complexType name="ComplexConfigDetail">
  <xs:sequence maxOccurs="1">
  <xs:element name="Frame" 
              type="xs:int" 
              minOccurs="0" 
              maxOccurs="1"/>
  </xs:sequence>
</xs:complexType>

预期的 FBS 架构：

namespace http_www_demo_com_config

table ComplexConfigDetail {
    DetailElement : int;
}

table Configuration {
    MandatoryInt : uint (required);
    OptionalInt : uint;
    MandatoryDetail : ComplexConfigDetail (required);
    OptionalDetail : ComplexConfigDetail;
    UnboundedDetail : [ComplexConfigDetail];
}

是否有这样的转换可用，例如 XSLT。

编辑： 感谢 Dan，我将他的 XSLT 扩展到这个也处理 xs:extensions （继承）

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
                xmlns:xs="http://www.w3.org/2001/XMLSchema" 
                version="1.0">

  <xsl:output method="text" omit-xml-declaration="yes" />

  <xsl:template match="/xs:schema">namespace http_www_demo_com_config;
    <xsl:apply-templates select="//xs:simpleType" />
    <xsl:apply-templates select="//xs:complexType" />
</xsl:template>

  <xsl:template match="xs:simpleType[xs:restriction/@base='xs:string' and count(xs:restriction/xs:enumeration) > 0]">
enum <xsl:value-of select="@name"/> : byte {
  <xsl:for-each select="xs:restriction/xs:enumeration" >
    <xsl:value-of select="@value"/>
      <xsl:if test="position() != last()">
        <xsl:text>,
  </xsl:text>
      </xsl:if>
    </xsl:for-each>
 }</xsl:template>

<xsl:template name="complexTypeMatch" match="xs:complexType">
table <xsl:value-of select="@name" /> {
<xsl:apply-templates select="xs:complexContent" />
  <xsl:apply-templates select="xs:sequence/xs:element" />
  <xsl:apply-templates select="xs:attribute" />  }
</xsl:template>

  <xsl:template match="xs:complexContent">
    <xsl:apply-templates  select="xs:extension"/>
  </xsl:template>

<xsl:template name="extensionType" match="xs:extension">
<xsl:apply-templates select="//xs:complexType[@name=current()/@base]/xs:complexContent" />
<xsl:apply-templates select="//xs:complexType[@name=current()/@base]/xs:sequence/xs:element"/>
<xsl:apply-templates select="//xs:complexType[@name=current()/@base]/xs:attribute"/>
</xsl:template>

<xsl:template match="xs:element | xs:attribute">
  <xsl:text>  </xsl:text>
  <xsl:value-of select="@name" /> : <xsl:if test="@maxOccurs != 1">[</xsl:if>
  <xsl:call-template name="typeTransformer">
    <xsl:with-param name="type" select="@type" />
  </xsl:call-template>
<xsl:if test="@maxOccurs != 1">]</xsl:if>
<xsl:if test="@minOccurs > 0"> (required)</xsl:if>
<xsl:text>;&#13;&#10;</xsl:text>
</xsl:template>

<xsl:template name="typeTransformer">
  <xsl:param name="type" />
  <xsl:choose>
      <xsl:when test="$type = 'xs:unsignedInt'"><xsl:text>uint</xsl:text></xsl:when>
      <xsl:when test="$type = 'xs:unsignedByte'"><xsl:text>ubyte</xsl:text></xsl:when>
      <xsl:when test="starts-with($type, 'xs:')"><xsl:value-of select="substring-after($type, 'xs:')" /></xsl:when>
  <xsl:otherwise>
    <xsl:value-of select="$type" />
  </xsl:otherwise>
</xsl:choose>

</xsl:template>
</xsl:stylesheet>
4

1 回答 1

1

写一个应该不会很复杂，例如：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="1.0">
  <xsl:output method="text" omit-xml-declaration="yes" />
  <xsl:template match="/xs:schema">
namespace http_www_demo_com_config
    <xsl:apply-templates />
  </xsl:template>
  <xsl:template match="xs:complexType">
table <xsl:value-of select="@name" /> {
    <xsl:apply-templates />
}
  </xsl:template>

  <xsl:template match="xs:element | xs:attribute">
    <xsl:value-of select="@name" /> : 
    <xsl:if test="@maxOccurs != 1">[</xsl:if>
    <xsl:call-template name="typeTransformer">
      <xsl:with-param name="type" select="@type" />
    </xsl:call-template>
    <xsl:if test="@maxOccurs != 1">]</xsl:if>
    <xsl:if test="@minOccurs > 0"> (required)</xsl:if>
    <xsl:text>&#13;&#10;</xsl:text>
  </xsl:template>

  <xsl:template name="typeTransformer">
    <xsl:param name="type" />
    <xsl:choose>
      <xsl:when test="$type = 'xs:unsignedInt'">
         <xsl:text>uint</xsl:text>
      </xsl:when>
      <xsl:when test="starts-with($type, 'xs:')">
         <xsl:value-of select="substring-after($type, 'xs:')" />
      </xsl:when>
      <xsl:otherwise>
         <xsl:value-of select="$type" />  
      </xsl:otherwise>
    </xsl:choose>

  </xsl:template>
</xsl:stylesheet>

只需扩展它choice以转换无法正确排列的其他特定属性值。

于 2017-03-24T16:30:39.373 回答