4

我可以编写 Prim 和 Kruskal 的算法来在 C++ 或 Java 中找到最小生成树，但我想知道如何在 Haskell 中用 O(mlogm) 或 O(mlogn) 实现它们（纯函数程序更好）。非常感谢。

4

3 回答 3

10

正如 svenningsson 所建议的， 优先级搜索队列非常适合 Kruskal 和 Prim 的（至少作者在他的论文中声明了它。） Kruskal 的问题是它需要你有一个 O(log n) union-find 算法。此处描述了具有纯函数式接口的 union-find 数据结构，但它在内部使用可变状态，纯函数式实现可能是不可能的，事实上，有几个问题是不知道有效的纯函数式解决方案的，如在这个相关的SO问题。

一个非纯替代方案是在 ST monad 中实现联合查找算法。在 Hackage 上搜索发现等价包适合我们的需要。以下是使用等效包中的 Data.Equivalence.Monad 的 Kruskal 实现：

import Data.Equivalence.Monad
import Data.Graph as G
import Data.List(sortBy)
import Data.Map as M
import Control.Monad(filterM)
import Data.Ord(comparing)

run = runEquivM (const ()) (const $ const ())

kruskal weight graph = run $
 filterM go (sortBy (comparing weight) theEdges)
     where
      theEdges = G.edges graph
      go (u,v) = do 
        eq <- equivalent u v
        if eq then return False else
         equate u v >> return True

它可以这样使用：

fromL xs = fromJust . flip M.lookup (M.fromList xs)

testWeights = fromL [((1,2),1),((2,3),4),((3,4),5),((1,4),30),((1,3),4)]
testGraph = G.buildG  (1,4) [(1,2),(2,3),(3,4),(1,4),(1,3)]
test = kruskal testWeights testGraph

运行测试给出：

[(1,2),(1,3),(3,4)]

应该注意的是，运行时间取决于在 O(1) 时间内运行的权重，但是fromL创建了在 O(log(n)) 时间内运行的权重函数，这可以通过使用数组或只是跟踪输入列表中的权重，但这并不是算法的一部分。

于 2010-11-27T19:21:41.470 回答
6

这是一个粗略的 Kruskal 实现。

import Data.List(sort)
import Data.Set (Set, member, fromList, insert, union)

data Edge a = Edge a a Double deriving Show

instance (Eq a) => Eq (Edge a) where
  Edge x1 y1 z1 == Edge x2 y2 z2 = x1 == x2 && y1 == y2 && z1 == z2

instance Eq a => Ord (Edge a) where
  (Edge _ _ x) `compare` (Edge _ _ y) = x `compare` y

kruskal :: Ord a => [Edge a] -> [Edge a]
kruskal = fst . foldl mst ([],[]) . sort

mst :: Ord a => ([Edge a],[Set a]) -> Edge a -> ([Edge a],[Set a])
mst (es, sets) e@(Edge p q _) = step $ extract sets where
   step (rest, Nothing, Nothing) = (e : es, fromList [p,q] : rest)
   step (rest, Just ps, Nothing) = (e : es, q `insert` ps : rest)
   step (rest, Nothing, Just qs) = (e : es, p `insert` qs : rest)
   step (rest, Just ps, Just qs) | ps == qs = (es, sets) --circle
                                 | otherwise = (e : es, ps `union` qs : rest)
   extract = foldr f ([], Nothing, Nothing) where
       f s (list, setp, setq) =
            let list' = if member p s || member q s then list else s:list
                setp' = if member p s then Just s else setp
                setq' = if member q s then Just s else setq
            in (list', setp', setq')

第一步是对边进行排序，即 O(n log n)。问题是在提取函数中找到更快的顶点集查找。我找不到更快的解决方案，也许有人有想法......

[更新]

对于 Scala 实现，我使用了类似地图的数据结构来（希望）获得更好的性能，但不幸的是它使用了可变集，我不知道如何将其转换为 Haskell。代码在我的博客中（对不起，描述是德语）：http ://dgronau.wordpress.com/2010/11/28/nochmal-kruskal/

于 2010-11-27T22:46:01.883 回答
3

我认为优先搜索队列是您正在寻找的。正如 Ralf Hinze 在一篇论文中所证明的那样，它可以用函数式语言最佳地实现。看来这篇论文只能通过 acm 的图书馆付费获得。

于 2010-11-27T17:31:46.833 回答