1

我有一个包含滑块的处理草图。生成此滑块的代码如下：

ControlP5 gui;
gui = new ControlP5(this);
gui.addSlider("Tolerance").setPosition(40, height-60).setSize(400, 20).setRange(0.00, 0.10).setValue(0.05).setNumberOfTickMarks(11).setSliderMode(Slider.FLEXIBLE);
gui.getController("Tolerance").getValueLabel().align(ControlP5.RIGHT, ControlP5.TOP_OUTSIDE).setPaddingX(0).setFont(font);
gui.getController("Tolerance").setCaptionLabel("Comparison Tolerance");
gui.getController("Tolerance").getCaptionLabel().align(ControlP5.LEFT, ControlP5.TOP_OUTSIDE).setPaddingX(0).setFont(font);

我遇到的问题0.08是当滑块同时位于0.08 TickMark和时显示该值0.09 TickMark。0.09是唯一显示不正确的值 - 请参见下图：

图片1

图片2

图3

图4

滑块实际上是0.09在上面第三张图中选择了正确的值，当滑块的位置打印到控制台时，但是这个显示错误令人困惑，并不理想。任何帮助将非常感激。

更新：我发现滑块右上角显示的值总是向下舍入。将滑块值输出到控制台时，这些值通常与预期的值略有不同 - 即在中心位置，打印到控制台的实际滑块值是0.0500003. 通过查看每个滑块位置的真实值，该0.09位置是唯一一个值低于预期值的位置 - 0.0899996。因此，这似乎被四舍五入0.08以显示该值。所以问题仍然存在 - 有没有办法根据0.09这些信息显示 的正确值？

4

1 回答 1

2

好眼力！也许您应该为开发人员发布一个问题。同时，您可以做的是继承 Slider 类并使用 Java 的DecimalFormat类来修复标签：

import java.text.DecimalFormat;
import controlP5.*;

ControlP5 gui;

void setup(){
  size(640,480);
  gui = new ControlP5(this);
  CustomSlider slider = new CustomSlider(gui,"Tolerance");

  slider.setPosition(40, height-60).setSize(400, 20).setRange(0.00, 0.10).setValue(0.05);
  slider.setFont(createFont("Verdana",12));
  slider.setNumberOfTickMarks(11).setSliderMode(Slider.FLEXIBLE);
  slider.getValueLabel().align(ControlP5.RIGHT, ControlP5.TOP_OUTSIDE).setPaddingX(0);
  slider.setCaptionLabel("Comparison Tolerance");
  slider.getCaptionLabel().align(ControlP5.LEFT, ControlP5.TOP_OUTSIDE).setPaddingX(0);
}
void draw(){
  background(0);
}

//subclass slider
public class CustomSlider extends Slider{

  //decimal format reference
  DecimalFormat df;

  //constructor
  public CustomSlider( ControlP5 cp5 , String name ) {
    super(cp5,name);
    //setup decimal format proof of concept - hardcoded fractional digits for now (this can be nicer)
    df = new DecimalFormat();
    df.setMaximumFractionDigits(2);
  }

  @Override public Slider setValue( float theValue ) {
    super.setValue(theValue);
    //this can be improved, follow the CP5 component lifecycle to determine when an instance initialised in the constructor is ready
    if(df != null){
      _myValueLabel.set( df.format(getValue( )));
    }else{
      _myValueLabel.set( getValue( ) +"" );
    }
    return this;
  }

}

预览

于 2017-03-13T21:08:41.930 回答