-1

我正在尝试永久更改用户窗体，以便我只需运行一次代码，而不是每次单击打开用户窗体的按钮时运行它。

我发现这对某些人有用。我不确定我可能有什么问题。

Sub FormatUserForms(UF As UserForm)

UF.BackColor = RGB(51, 51, 102)
Dim ctrl As Control

With ThisWorkbook.VBProject.VBComponents("UFNewRequest").Designer
    For Each ctrl In UF.Controls
        Select Case TypeName(ctrl)
            Case "Label"
                ctrl.BackColor = RGB(51, 51, 102)
                ctrl.ForeColor = RGB(247, 247, 247)
            Case "CommandButton"
                ctrl.BackColor = RGB(247, 247, 247)
                ctrl.ForeColor = RGB(0, 0, 0)
            Case "TextBox"
                ctrl.BackColor = RGB(247, 247, 247)
                ctrl.ForeColor = RGB(0, 0, 0)
            Case "OptionButton"
                ctrl.BackColor = RGB(51, 51, 102)
                ctrl.ForeColor = RGB(247, 247, 247)
        End Select
    Next
End With
End Sub

Sub formatting()

FormatUserForms UFNewRequest

End Sub

感谢您对此的任何帮助！

4

1 回答 1

1

你混合了两件事。这是使用该ThisWorkbook.VBProject.VBComponents("UFNewRequest").Designer对象的正确轨道，但您没有使用它。相反，您的代码适用于作为参数传递的表单 - 这仅在运行时有效。

Sub FormatUserForm(frm As Object)

Dim d As UserForm
Set d = frm.Designer

d.BackColor = RGB(51, 51, 102)

Dim ctrl As Control
For Each ctrl In d.Controls
    Select Case TypeName(ctrl)
            (...)
    End Select
Next ctrl

End Sub

您可以为项目中的所有表单调用该函数：

Dim f As Object
For Each f In ThisWorkbook.VBProject.VBComponents
    If f.Type = 3 Then
       Call FormatUserForm(f)
    End If
Next f

我想有一种方法可以为 f 使用早期绑定，但是您必须在项目中添加对 VBE 的引用，并且我不允许在我的计算机上执行此操作，因此我无法测试。可能也为魔术类型 3 (=forms) 定义了一个常量

于 2017-02-24T16:35:32.840 回答