0

我有三个表格，如下所示：

     A   B   C             A   B   C              A    B    C     
D    1   2   3        D    2   3   4         D    3    4    5
E    4   5   6        E    5   6   7         E    6    7    8 
F    7   8   9        F    8   9   10        F    9    10   11

我想在 SAS 中逐个单元格地找到这些表的平均值。所以输出应该如下所示：

     A   B   c
D    2   3   4
E    5   6   7 
F    8   9   10

因此，例如，第一个单元格将计算如下 (1 + 2 + 3) / 3 = 3

目前我完全不知道如何做到这一点，但我正在研究 proc mean 和 proc freq，这似乎很有希望。

预先感谢您的帮助。

4

1 回答 1

1

在 SAS/IML 中，这是微不足道的。

proc iml;
  a = {1 2 3,4 5 6,7 8 9};
  b = {2 3 4,5 6 7,8 9 10};
  c = {3 4 5,6 7 8,9 10 11};
  d = (a+b+c)/3;
 print a b c d;
quit;

在 SQL 或基本 SAS 中，也有一些方法可以解决它，假设您输入了第三个数据集（DFG 应该是 DEF）。如果你没有打错，那就更难了。

data a;
input ID $ a b c;
datalines;
D    1   2   3 
E    4   5   6 
F    7   8   9 
;;;;
run;

data b;
input ID $ a b c;
datalines;
D    2   3   4   
E    5   6   7   
F    8   9   10  
;;;
run;

data c;
input ID $ a b c;
datalines;
D    3    4    5
E    6    7    8 
F    9    10   11
;;;;
run;

data for_d;
  set a b c;
  by id;
run;

proc means data=for_d;
  var a b c;
  class ID;
  output out=d mean=;
run;

SQL 解决方案需要更多输入，但最终相似（您可以跳过该for_d步骤）。只需将 a、b、c 连接在一起并计算查询中的平均值。

于 2017-02-20T16:56:26.407 回答