6

我想做的是智能地为compile函数的字符串参数预先设置一个缓冲区本地默认值。

现在 compile.el 默认使用“make”作为命令。我可以通过设置来设置compile-command。我什至可以使该变量成为局部缓冲区。如果我想要相同的静态值，那总是有效的。

但我想compile-command根据缓冲区的内容、缓冲区的名称、文件包含目录的内容（如果有）和月相来智能地选择。基本上我想控制默认值，然后允许交互式用户覆盖该预设值。

我希望通过事先的建议来做到这一点。但这并没有像我预期的那样工作。

阅读advice.el文件，我明白了

假设一个函数/宏/subr/特殊形式有 N 条前通知，M 条环绕通知和 K 条后通知。假设没有任何建议受到保护，其建议定义将如下所示（主体形式索引对应于该建议类中相应建议的位置）：

([macro] lambda <arglist>
   [ [<advised-docstring>] [(interactive ...)] ]
   (let (ad-return-value)
 {<before-0-body-form>}*
       ....
 {<before-N-1-body-form>}*
 {<around-0-body-form>}*
    {<around-1-body-form>}*
      ....
       {<around-M-1-body-form>}*
      (setq ad-return-value
        <apply original definition to <arglist>>)
       {<other-around-M-1-body-form>}*
      ....
    {<other-around-1-body-form>}*
 {<other-around-0-body-form>}*
 {<after-0-body-form>}*
       ....
 {<after-K-1-body-form>}*
 ad-return-value))

这对我说的是，当建议函数是交互式的时，“交互式调用”会在调用之前的建议或任何建议之前调用交互式表单。

而且，当我向 中添加建议时compile，我观察到的行为证实了这一点。在处理交互式表单后调用建议。在我的建议有机会猜测它应该是什么并预先设置之前，交互式表单会建议用于编译的字符串。

所以...

  • 如何让我的代码在交互式表单之前运行？可以建议吗？如果不是建议，还有别的吗？或者
  • 如何compile-command为任何缓冲区动态预设？

想法赞赏。

4

5 回答 5

5

compile-command一种选择是在模式挂钩中设置变量，例如

(add-hook 'c++-mode-hook 'my-c++-set-compile-command)
(defun my-c++-set-compile-command ()
   (setq (make-local-variable 'compile-command) (format "gmake %s" (buffer-file-name))))

我有时会添加专门的命令来调整当前编译行（打开/关闭调试标志、优化标志等），然后将这些命令绑定到迷你缓冲区中方便的击键。

关于在interactive表单之前添加建议，您需要提供具有您想要的交互式表单的建议（之前或周围）。来自advice.el 库的示例：

;;(defadvice switch-to-buffer (around confirm-non-existing-buffers activate)
;;  "Switch to non-existing buffers only upon confirmation."
;;  (interactive "BSwitch to buffer: ")
;;  (if (or (get-buffer (ad-get-arg 0))
;;          (y-or-n-p (format "`%s' does not exist, create? " (ad-get-arg 0))))
;;      ad-do-it))
于 2010-11-20T17:39:55.677 回答
5

compile-command 不必是字符串。compile 函数对其进行评估，因此它可以是返回特定于缓冲区或取决于一天中的时间等的字符串的函数：

(setq compile-command (lambda () (if (eq phase-of-moon 'waning) 
                                     "make -DWANING=1" 
                                    "make -DWANING=0")))

此外，虽然可能对您的特定需求没有用处，但您始终可以在文件变量部分定义 compile-command：

/* -*- compile-command: "make -DFOO"; -*- */

或者

// Local Variables:
// compile-command: "make -DSOMETHING_SPECIAL"
// End:

compile-command 实际上在手册中用作文件变量的示例。

于 2012-12-06T23:29:49.433 回答
4

啊，你知道我做了什么吗？我使用了倾斜策略。

我已将 C-xC-e 全局设置为compile. 我没有使用建议，而是定义了一个 wrap 的函数，compile然后将 C-xC-e 绑定到该. 在包装器中，我猜测编译命令。 

(defun cheeso-invoke-compile-interactively ()
  "fn to wrap the `compile' function.  This simply
checks to see if `compile-command' has been previously guessed, and
if not, invokes `cheeso-guess-compile-command' to set the value.
Then it invokes the `compile' function, interactively."
  (interactive)
  (cond
   ((not (boundp 'cheeso-local-compile-command-has-been-set))
(cheeso-guess-compile-command)
(set (make-local-variable 'cheeso-local-compile-command-has-been-set) t)))
  ;; local compile command has now been set
  (call-interactively 'compile))

而guess函数是这样的：

(defun cheeso-guess-compile-command ()
  "set `compile-command' intelligently depending on the
current buffer, or the contents of the current directory."
  (interactive)
  (set (make-local-variable 'compile-command)
   (cond
    ((or (file-expand-wildcards "*.csproj" t)
     (file-expand-wildcards "*.vcproj" t)
     (file-expand-wildcards "*.vbproj" t)
     (file-expand-wildcards "*.shfbproj" t)
     (file-expand-wildcards "*.sln" t))
     "msbuild ")

    ;; sometimes, not sure why, the buffer-file-name is
    ;; not set.  Can use it only if set.
    (buffer-file-name
     (let ((filename (file-name-nondirectory buffer-file-name)))
       (cond

    ;; editing a .wxs (WIX Soluition) file
    ((string-equal (substring buffer-file-name -4) ".wxs")
     (concat "nmake "
         ;; (substring buffer-file-name 0 -4) ;; includes full path
         (file-name-sans-extension filename)
         ".msi" ))

    ;; a javascript file - run jslint
    ((string-equal (substring buffer-file-name -3) ".js")
     (concat (getenv "windir")
         "\\system32\\cscript.exe c:\\cheeso\\bin\\jslint-for-wsh.js "
         filename))

    ;; something else - do a typical .exe build
    (t
     (concat "nmake "
         (file-name-sans-extension filename)
         ".exe")))))

    (t
     "nmake "))))
于 2010-11-20T16:48:00.087 回答
1

这是我正在使用的一些代码，它可以智能地选择由怀俄明大学提供的编译命令。我目前已将其设置为C, C++, 和Fortran。您可以添加更多以满足您的需求。如果我打开一个具有C++扩展名的程序并执行M-xcompile，我的编译命令就会出现g++ -Wall currentfilename.cpp -o currentfilename -std=c++14。然后我只需要打enter。

;; M-x compile smarter in order to guess language
(require 'compile)
(defvar compile-guess-command-table
  '((c-mode       . "gcc -Wall -g %s -o %s -lm")
    (c++-mode     . "g++ -Wall %s -o %s -std=c++14")
    (fortran-mode . "gfortran -C %s -o %s")
    ))

(defun compile-guess-command ()
  (let ((command-for-mode (cdr (assq major-mode
                                     compile-guess-command-table))))
    (if (and command-for-mode
             (stringp buffer-file-name))
        (let* ((file-name (file-name-nondirectory buffer-file-name))
               (file-name-sans-suffix (if (and (string-match "\\.[^.]*\\'"
                                                             file-name)
                                               (> (match-beginning 0) 0))
                                          (substring file-name
                                                     0 (match-beginning 0))
                                        nil)))
          (if file-name-sans-suffix
              (progn
                (make-local-variable 'compile-command)
                (setq compile-command
                      (if (stringp command-for-mode)
                          ;; Optimize the common case.
                          (format command-for-mode
                                  file-name file-name-sans-suffix)
                        (funcall command-for-mode
                                 file-name file-name-sans-suffix)))
                compile-command)
            nil))
      nil)))


;; Add the appropriate mode hooks.
(add-hook 'c-mode-hook       (function compile-guess-command))
(add-hook 'c++-mode-hook     (function compile-guess-command))
(add-hook 'fortran-mode-hook (function compile-guess-command))
于 2015-04-18T04:21:50.833 回答
0

根据手册，您可以通过在您的建议中包含交互式表单来简单地用您自己的函数覆盖函数的交互式表单。我认为您不能修改或包装现有的交互式表单，只能完全覆盖它。

http://www.gnu.org/software/emacs/manual/html_node/elisp/Defining-Advice.html

于 2014-08-11T15:41:18.893 回答