automator - 在 Automator 中创建以指定文件名命名的新文件夹

Question

我想创建一个以用于输入的文件的文件名命名的新文件夹。

例子：

如果我将新服务与文件“test (test).jpg”一起使用，我想自动创建一个名为“test (test)”的文件夹。

Answer 1

要使用常规 Automator 操作执行此操作，它会有点复杂，因为您需要保存原始输入、获取名称、创建文件夹、取回原始输入等。您可以使用Run AppleScript操作来完成大部分操作一口气，尽管这取决于您要对原始输入和创建的文件夹路径做什么。

以下运行 AppleScript操作将使用输入项的名称创建新文件夹（请注意，服务可以传递多个项），并且仅传递原始输入。新文件夹在同一个父文件夹中创建 - 不执行错误处理（重复名称等）：

on run {input, parameters} -- make new folders from base file names

    set output to {}

    repeat with anItem in the input -- step through each item in the input

        set anItem to anItem as text
        tell application "System Events" to tell disk item anItem
            set theContainer to path of container
            set {theName, theExtension} to {name, name extension}
        end tell
        if theExtension is in {missing value, ""} then
            set theExtension to ""
        else
            set theExtension to "." & theExtension
        end if
        set theName to text 1 thru -((count theExtension) + 1) of theName -- the name part

        tell application "Finder"
            make new folder at folder theContainer with properties {name:theName}
            set end of output to result as alias
        end tell
    end repeat

    return input -- or output
end run