1

我正在尝试从http://isthe.com/chongo/tech/comp/fnv/实现 FNV 哈希

我将该页面上的 PowerBasic 的内联汇编转换为 Delphi。

    function ReadFileToMem(sPath:string):Pointer;
    var
    hFile:    THandle;
    pBuffer:  Pointer;
    dSize:    DWORD;
    dRead:    DWORD;
    begin
    hFile := CreateFile(PChar(sPath), GENERIC_READ, FILE_SHARE_READ, nil, OPEN_EXISTING, 0, 0);
    if hFile <> 0 then
        dSize := GetFileSize(hFile, nil);
        if dSize <> 0 then
        begin
          SetFilePointer(hFile, 0, nil, FILE_BEGIN);
          GetMem(Result, dSize);
          ReadFile(hFile, Result^, dSize, dRead, nil);
          if dRead = 0 then
            MessageBox(0, PChar('Error reading file.'), PChar('Read Error'), MB_ICONEXCLAMATION)
         end;
        CloseHandle(hFile);
    end;

    function GetPointerSize(lpBuffer: Pointer): Cardinal; // Function by ErazerZ
    begin
      if lpBuffer = nil then
        Result := Cardinal(-1)
      else
        Result := Cardinal(Pointer(Cardinal(lpBuffer) -4)^) and $7FFFFFFC -4;
    end;

     FUNCTION FNV32( dwOffset : Pointer; dwLen : DWORD; offset_basis : DWORD) : DWORD ;
      asm
     mov esi, dwOffset      //;esi = ptr to buffer
     mov ecx, dwLen         //;ecx = length of buffer (counter)
     mov eax, offset_basis  //;set to 2166136261 for FNV-1
     mov edi, 16777619//&h01000193    //;FNV_32_PRIME = 16777619
     xor ebx, ebx           //;ebx = 0
      @nextbyte:
     mul edi                //;eax = eax * FNV_32_PRIME
     mov bl, [esi]          //;bl = byte from esi
     xor eax, ebx           //;al = al xor bl
     inc esi                //;esi = esi + 1 (buffer pos)
     dec ecx                //;ecx = ecx - 1 (counter)
     jnz @nextbyte           //;if ecx is 0, jmp to NextByte
     mov @result, eax      //;else, function = eax

    end;

procedure TForm1.Button1Click(Sender: TObject);
var
pFile : Pointer;
hFile : Cardinal;
begin
//Profiler1['Test'].Start;
pFile := ReadFileToMem(fn);
hFile := FNV32(pFile,GetPointerSize(pFile),2166136261);
//Profiler1['Test'].Stop;
//OutputDebugString(pchar(Profiler1['Test'].AsText[tiAll]));
OutputDebugString(pchar(inttostr(hFile)));
end;

如果给定文件的大小超过 200KB，则输出是随机（散列）数。我错过了什么吗？

4

3 回答 3

4

恕我直言，您的 asm 代码有些错误。正如它所写的那样，它会使您的应用程序崩溃。

  • 您需要保留 esi/edi/ebx 寄存器
  • 参数在 eax,ecx,edx 寄存器中传递
  • 结果是 eax 寄存器

正确的做法可能是（未经测试，只是写在这里）：

function fnv32(dwOffset : Pointer; dwLen : DWORD; offset_basis: DWORD) : DWORD ;
asm // eax=dwOffset ecx=dwLen edx=offset_basis -> result in eax
  push esi
  push edi
  mov esi,eax
  mov eax,edx
  or ecx,ecx
  je @z
  mov edi,16777619
  xor edx,edx
@1:
  mul edi
  mov dl,[esi]
  xor eax,edx
  inc esi
  dec ecx
  jnz @1
@z:
  pop edi
  pop esi
end;

因此，要以纯 Delphi 方式读取和散列任何文件（不要像以前那样使用 Windows API）：

function fnv32file(const aFileName: TFileName): DWORD;
begin
  with TMemoryStream.Create do
  try
    LoadFromFile(aFileName);
    result := fnv32(Memory,Size,0);
  finally
    Free;
  end;
end;

恕我直言，纯帕斯卡版本不会慢很多（瓶颈肯定是从硬盘驱动器读取数据）：

function fnv32(dwOffset : PByteArray; dwLen : DWORD; offset_basis: DWORD): DWORD ;
var i: integer;
begin
  result := offset_basis;
  for i := 0 to dwLen-1 do
    result := (result*16777619) xor DWORD(dwOffset^[i]);
end;
于 2010-11-16T08:18:39.397 回答
1

我应该从哪里开始...

1) CreateFile 在失败时返回 INVALID_HANDLE_VALUE，而不是 0。

2) SetFilePointer 不是必需的。

3）如果您必须散列 16 GB 文件怎么办？

4) 您没有释放分配的内存 - FreeMem(pFile)。

5) GetPointerSize 是一个彻底的黑客。您可以只从 ReadFileToMem 返回文件大小。

以下代码是对您的方法的重写。它仍然将完整的文件加载到内存中，但以“Delphi 方式”实现。

function ReadFileToMem(const sPath: string; var buffer: TMemoryStream): boolean;
var
  fileStr: TFileStream;
begin
  Result := false;
  try
    fileStr := TFileStream.Create(sPath, fmOpenRead);
    try
      buffer.Size := 0;
      buffer.CopyFrom(fileStr, 0);
    finally FreeAndNil(fileStr); end;
    Result := true;
  except
    on E: EFOpenError do
      ShowMessage('Error reading file. ' + E.Message);
  end;
end;

function FNV32(dwOffset: pointer; dwLen: cardinal; offset_basis: cardinal): cardinal;
asm
  mov esi, dwOffset      //;esi = ptr to buffer
  mov ecx, dwLen         //;ecx = length of buffer (counter)
  mov eax, offset_basis  //;set to 2166136261 for FNV-1
  mov edi, 16777619//&h01000193    //;FNV_32_PRIME = 16777619
  xor ebx, ebx           //;ebx = 0
@nextbyte:
  mul edi                //;eax = eax * FNV_32_PRIME
  mov bl, [esi]          //;bl = byte from esi
  xor eax, ebx           //;al = al xor bl
  inc esi                //;esi = esi + 1 (buffer pos)
  dec ecx                //;ecx = ecx - 1 (counter)
  jnz @nextbyte           //;if ecx is 0, jmp to NextByte
  mov @result, eax      //;else, function = eax
end;

procedure TForm16.Button1Click(Sender: TObject);
var
  hFile : cardinal;
  memBuf: TMemoryStream;
begin
  memBuf := TMemoryStream.Create;
  try
    if ReadFileToMem('SomeFile', memBuf) then begin
      hFile := FNV32(memBuf.Memory, memBuf.Size, 2166136261);
      ShowMessageFmt('Hash = %d', [hFile]);
    end;
  finally FreeAndNil(memBuf); end;
end;
于 2010-11-16T07:16:40.633 回答
1

享受

function fnv(dwOffset : Pointer; dwLen : NativeUInt; offset_basis: NativeUInt) : NativeUInt ;
//
// http://find.fnvhash.com/ - FNV Hash Calculator Online
// http://www.isthe.com/chongo/tech/comp/fnv/
//
// The offset_basis for FNV-1 is dependent on n, the size of the hash:
// 32 bit offset_basis = 2166136261
// 64 bit offset_basis = 14695981039346656037
//
{$IF Defined(CPUX86)}
asm
    push ebp
    push edi
    push ebx // statement must preserve the EDI, ESI, ESP, EBP, and EBX registers
    mov ebp, edx
    mov edx, ecx // but can freely modify the EAX, ECX, and EDX registers
    mov ecx, eax
    mov eax, edx
    mov edi, 01000193h
    xor ebx, ebx
  @@nexta:
    mov bl, byte ptr [ecx]
    xor eax, ebx
    mul edi
    inc ecx
    dec ebp
    jnz @@nexta
    pop ebx
    pop edi
    pop ebp
end;
{$ELSEIF Defined(CPUX64)}
asm
    mov rax, R8
    mov r8, rdx
    mov r9, 100000001b3h
    xor r10, r10
  @@nexta:
    mov r10b, byte ptr [rcx]
    xor rax, r10
    mul r9
    inc rcx
    dec r8
    jnz @@nexta
end;
{$IFEND}
于 2015-04-10T09:07:42.657 回答