3

我是贝叶斯分析的新手，正在尝试使用 rstan 来估计后验密度分布。该练习试图重新创建我的大学使用 stan 提供给我们的示例，但我对如何正确转换变量有点困惑。我当前的代码运行没有错误，但结果与大学给出的结果不匹配（尽管很接近），为了清楚起见，下图以黑色显示 stan 估计。我通过查阅手册并将随机位拼凑在一起使代码工作，但特别是我不太确定为什么target需要以及伽玛的转换是否确实正确。任何指导将不胜感激！

模型

在此处输入图像描述

斯坦代码 

data {
  int<lower=0> I;
  int<lower=0> n[I];
  int<lower=0> x[I];
  real<lower=0> a;
  real<lower=0> b;
  real m;
  real<lower=0> p;
}

parameters {
  real<lower=0> lambda;
  real mu;
  real<lower=0, upper=1> theta[I];
}

transformed parameters {
  real gam[I];
  for( j in 1:I)
   gam[j] = log(theta[j] / (1-theta[j])) ;
}


model {
  target +=  gamma_lpdf( lambda |  a, b);
  target +=  normal_lpdf( mu | m , 1/sqrt(p));
  target +=  normal_lpdf( gam | mu, 1/sqrt(lambda));
  target +=  binomial_lpmf( x | n , theta);
}

R代码 

library(rstan)
fit <- stan(
  file = "hospital.stan" , 
  data = dat , 
  iter = 20000,
  warmup = 2000,   
  chains = 1
)

数据 

structure(
  list(
      I = 12L, 
      n = c(47, 211, 810, 148, 196, 360, 119,  207, 97, 256, 148, 215), 
      x = c(0, 8, 46, 9, 13, 24, 8, 14, 8, 29, 18, 31), 
      a = 2, 
      b = 2, 
      m = 0, 
      p = 0.01), 
  .Names = c("I", "n", "x", "a", "b", "m", "p")
)

---更新解决方案---

Ben Goodrich 指出的问题是我从 theta 推导出 gamma，因为它应该是相反的，因为 gamma 是我的随机变量。正确的 stan 代码如下。

data {
    int<lower=0> I;
    int<lower=0> n[I];
    int<lower=0> x[I];
    real<lower=0> a;
    real<lower=0> b;
    real m;
    real<lower=0> p;
}

parameters {
    real<lower=0> lambda;
    real mu;
    real gam[I];
}

transformed parameters {
    real<lower=0 , upper=1> theta[I];
    // theta = inv_logit(gam);  // Alternatively can use the in-built inv_logit function which is vectorised
    for(j in 1:I){
        theta[j] = 1 / ( 1 + exp(-gam[j]));
    }
}

model {
    target +=  gamma_lpdf( lambda |  a, b);
    target +=  normal_lpdf( mu | m , 1/sqrt(p));
    target +=  normal_lpdf( gam | mu, 1/sqrt(lambda));
    target +=  binomial_lpmf( x | n ,  theta );
}
4

1 回答 1

3

作为提示，尝试将gam(ma) 放入parameters块中，然后根据您在一开始提供的分布theta在块中声明和定义。transformed parameters

Stan 的初学者通常认为 Stan 有能力从逻辑上计算出您的 Stan 程序的含义，而实际上它被完全按字面意思转换为 C++，并且代码行transformed parameters和model块被一遍又一遍地执行。

gam（ma）或者是原始参数之所以会有所不同theta，这与变量变化原理有关。如果您真的想要，如果您将雅可比行列式项（以对数单位）添加到 ，您可以使用原始参数化获得相同的结果，但通过将(ma) 移动到块和块来target更容易避免这种情况。有关变量变化原理的详细信息，请参阅此案例研究。gamparametersthetatransformed parameters

于 2017-01-25T01:22:23.620 回答