1

当我在 F# 中定义递归函数时：

let rec recursiveSum inputs =
    let startState = 0.0m

    if List.length inputs = 1 then
        startState + inputs.Head
    else
        let t = List.tail inputs
        startState + inputs.Head + recursiveSum t

...一切都很好。当我试图避免“空列表”问题时：

let rec recursiveSum inputs =
    let startState = 0.0m

    **if List.isEmpty inputs then startState**

    if List.length inputs = 1 then
        startState + inputs.Head
    else
        let t = List.tail inputs
        startState + inputs.Head + recursiveSum t

......我被大喊大叫：

recursion.fsx(5,9): error FS0001: This expression was expected to have type
    unit    
but here has type
    decimal

我在这里想念什么？

4

2 回答 2

3

从文档：

每个分支中产生的值的类型必须匹配。如果没有显式else分支，则其类型为unit. 因此，如果then分支的类型是 以外的任何类型unit，则必须存在else具有相同返回类型的分支。

你失踪说else。

let rec recursiveSum inputs =
    let startState = 0.0m

    if List.isEmpty inputs then 0.0m
    elif List.length inputs = 1 then
        startState + inputs.Head
    else
        let t = List.tail inputs
        startState + inputs.Head + recursiveSum t

（注意，我在elif这里使用了而不是嵌套另一个if表达式；希望这不会让人分心。）

也就是说，您涉及的逻辑startState非常可疑；它总是为零，在这里真的没有用。您的状态可能应该是一个参数而不是本地值，因此它可以用作累加器：

let recursiveSum inputs =
    let rec impl state inputs =
        if List.isEmpty inputs then state
        elif List.length inputs = 1 then
            state + inputs.Head
        else
            let t = List.tail inputs
            impl (state + inputs.Head) t
    impl 0.0m inputs

最后，让我们让它地道：

let recursiveSum inputs =
    let rec impl state inputs =
        match inputs with
          | []   -> state
          | [h]  -> state + h
          | h::t -> impl (state + h) t
    impl 0.0m inputs

可以缩短为

let recursiveSum inputs =
    let rec impl state = function
      | []   -> state
      | h::t -> impl (state + h) t
    impl 0.0m inputs
于 2017-01-23T19:57:51.990 回答
2

有了 ildjarns 的回答，我想我会建议一个人可以/应该一路走下去……

let rec fold f acc = function 
        | [] -> acc
        | [x] -> f x acc
        | h::t -> fold f (f h acc) t




let someDec = [0.1m; 0.2m]
let someStr = ["world"; "Hello "]

someDec
|> fold (+) 0.0m

someStr
|> fold (+) ""


let recursiveSum = fold (+) 0.0m    

someDec
|> recursiveSum


let recursiveStrAdd = fold (+) ""

someStr
|> recursiveStrAdd


someDec
|> recursiveSum

（而且我从不记得这里的左右，所以...... ;-)

于 2017-01-23T21:39:00.827 回答