1

我们正在开发 Beckhoff TwinCAT3 中的数据记录应用程序。要获取我们当前使用 LTIME() 的时间，然后使用 C# 将其转换为 ms：

ulong valA = reader.ReadUInt64();   // this gets the LTIME
long ftime = (long)(valA / 100);
DateTime t = DateTime.FromFileTime(ftime);
return (t.ToUniversalTime().Ticks - 621355968000000000) / 10000;

一定会有更好的办法。此外，我们看到此时间与计算机时间（任务栏中的时间）之间存在差异。

从计算机时钟获取自 1970 年（格林威治标准时间）以来的毫秒的最佳方法是什么？

我看到NT_GetTime。看起来我们需要对结构进行数学运算

感谢您的任何指示。

4

1 回答 1

3

关键是使用FB_TzSpecificLocalTimeToFileTime使用当前时区信息 ( ST_TimeZoneInformation )将当前T_FILETIME 转换为 UTC 。这将为您提供一个 UTC windows 文件时间（滴答声），需要将其转换为 UTC unix 时间。

这是此过程的功能块实现：

宣言

FUNCTION_BLOCK UnixTimestamp
VAR_OUTPUT
    seconds: ULINT;
    milliseconds: ULINT;
END_VAR

VAR
    localSystemTime : FB_LocalSystemTime := ( bEnable := TRUE, dwCycle := 1 );
    getTimeZoneInformation : FB_GetTimeZoneInformation;
    timeZoneInformation : ST_TimeZoneInformation;
    specificLocalTimeToFileTime : FB_TzSpecificLocalTimeToFileTime;
    fileTime: T_FILETIME;
    onZerothSecondLastCycle : BOOL;
END_VAR

执行

// Get local system time
localSystemTime();

// On the zeroth second of each minutesync timezone information
IF (timeZoneInformation.standardName = '' OR (localSystemTime.systemTime.wSecond = 0 AND NOT onZerothSecondLastCycle)) THEN
    getTimeZoneInformation(sNetID := '', bExecute := TRUE, tzInfo => timeZoneInformation);
END_IF;

// Convert local system time to unix timestamps
specificLocalTimeToFileTime(in := Tc2_Utilities.SYSTEMTIME_TO_FILETIME(localSystemTime.systemTime), tzInfo := timeZoneInformation, out => fileTime);
seconds := (SHL(DWORD_TO_ULINT(fileTime.dwHighDateTime), 32) + DWORD_TO_ULINT(fileTime.dwLowDateTime)) / 10000000 - 11644473600;
milliseconds := (SHL(DWORD_TO_ULINT(fileTime.dwHighDateTime), 32) + DWORD_TO_ULINT(fileTime.dwLowDateTime)) / 10000 - 11644473600000;

onZerothSecondLastCycle := localSystemTime.systemTime.wSecond = 0;

用法

VAR
    unixTime: UnixTimestamp;
    timestampSeconds: ULINT;
    timestampMilliseconds: ULINT;
END_VAR

-----

unixTime();
timestampMilliseconds := unixTime.milliseconds;
timestampSeconds := unixTime.seconds;
于 2017-01-20T23:00:21.180 回答