6

如何用一组值初始化向量？

我试过了，它符合要求，但不起作用！

 langs = new Vector.<String>(["en","fr"]);

我还需要将任意数组加载到向量中，如下所示：

 langlist = ["en","fr"];
 langs = new Vector.<String>(langlist);

有没有办法做到这一点？

编辑：如何用二维值数组初始化二维向量？

 numbers = [[10,20,30], [10,20,30]];
 nums = Vector.<Vector.<Number>>(numbers);

我试过这个，但它给了我错误：

TypeError：错误 #1034：类型强制失败

4

4 回答 4

49

初始化字符串向量的适当语法是这样的：

var langs:Vector.<String> = new <String>[ "en","fr" ];

为了创建多维向量，请使用以下语法：

var v:Vector.<Vector.<int>> = new <Vector.<int>>[ new <int>[ 1, 2, 3 ], new <int>[ 4, 5, 6 ] ];

请注意，以下语法有效，但不太理想，因为它首先生成一个数组，然后将其转换为一个向量，这比较慢，对非常大的数组有问题，并且不支持多维向量。

var langs:Vector.<String> = Vector.<String>( [ "en","fr" ] );
于 2011-06-07T14:05:05.147 回答
4

您可以使用全局函数Vector.<T>从数组中初始化 a ：Vector.<T>

var vec : Vector.<String> = Vector.<String>(["en","fr"]);
于 2010-11-13T18:21:24.397 回答
3

我不认为您可以将数组数组传递给Vector：

Vector.<Vector.<Number>>

类型强制不适用于复杂类型。如果您已经拥有 2D 数组，请考虑以下转换代码：

var numbers:Array = [[1, 2, 3], [4, 5, 6]];
var numbersTemp:Array =
numbers.map(
    function (element:*, index:int, arr:Array):Vector.<Number> {
    return Vector.<Number>(element);
});
var nums:Vector.<Vector.<Number>> = Vector.<Vector.<Number>>(numbersTemp);

当然，这会导致所有内容的新副本被创建两次，因此理想情况下您不会转换大列表。

于 2010-11-14T08:47:12.917 回答
2

从值列表初始化 Vector 的最干净、最快和最类型安全的方法是：

langs = new <String> ["en","fr"];

它不会创建一个临时数组来初始化新的向量，所以它会生成最快的字节码，并且不会用无用的临时数组实例来打扰垃圾收集器。它与以下一样快，但更实用：

langs = new Vector.<String>(2);
langs[0] = "en";
langs[1] = "fr";

最重要的是，它将在编译时执行类型检查，并减少出现运行时错误的机会

对于 2D 向量，没有直接的语法，因此您必须显式创建每个向量：

nums = new <Vector.<Number> > [new <Number>[10,20,30], new <Number>[10,20,30]];

您可以在此处获得有关非空向量初始化性能以及其他解决方案速度较慢的原因的深入信息：

http://jacksondunstan.com/articles/702

PS：如果没有用空格分隔，旧的 mxmlc 编译器将无法理解右括号：

new <Vector.<Number>>

于 2014-06-25T16:35:18.397 回答