4

我在类似的行中发现了其他问题，但在这种特定情况下没有任何问题可以回答我的问题。此外，似乎很少有资源能够简洁地涵盖 Haskell 中单元测试 IO 操作的主题。

假设我有这个类型类用于我的数据库通信：

data Something = Something String deriving Show

class MonadIO m => MonadDB m where
  getSomething :: String -> m Something
  getSomething s = do
    ... -- assume a DB call is made and an otherwise valid function

instance MonadDB IO

以及使用它的这个函数：

getIt :: MonadDB m => m (Int, Something)
getIt = do
  s@(Something str) <- getSomething "hi"
  return (length str, s) -- excuse the contrived example

我希望getIt用 hspec 测试这个函数，但没有它与数据库通信，这可能意味着替换MonadDB它使用的，但我该如何实现呢？

4

1 回答 1

6

这对你有用吗？

#!/usr/bin/env stack
-- stack exec --package transformers --package hspec -- ghci
import Control.Monad.IO.Class
import Control.Monad.Trans.Identity

import Data.Char
import Test.Hspec

data Something = Something String deriving (Eq, Show)

class MonadIO m => MonadDB m where
  getSomething :: String -> m Something
  getSomething s = return $ Something (map toUpper s)

instance MonadDB IO

instance MonadIO m => MonadDB (IdentityT m)

getIt :: MonadDB m => m (Int, Something)
getIt = do
  s@(Something str) <- getSomething "hi"
  return (length str, s)

main :: IO ()
main = hspec $ do
  describe "Some tests" $ do
    it "test getIt" $ do
      runIdentityT getIt `shouldReturn` (2, Something "HI")

    it "test getIt should fail" $ do
      runIdentityT getIt `shouldReturn` (1, Something "HI")

您还可以使用ReaderT或StateT“提供”数据或转换getSomething以在测试查询时使用。

编辑：hspec 中的示例使用。

于 2017-01-17T14:11:48.633 回答