3

我正在阅读带有管道 csv 库的 csv 文件。我想阅读第一行，然后再阅读其余部分。不幸的是 Pipes.Prelude.head 函数返回后。管道正在以某种方式关闭。有没有办法先读取 csv 的头部，然后再读取其余部分。

import qualified Data.Vector as V
import Pipes
import qualified Pipes.Prelude as P
import qualified System.IO as IO
import qualified Pipes.ByteString as PB
import qualified Data.Text as Text
import qualified Pipes.Csv as PCsv
import Control.Monad (forever)

showPipe :: Proxy () (Either String (V.Vector Text.Text)) () String IO b
showPipe = forever $ do
    x::(Either String (V.Vector Text.Text)) <- await
    yield $ show x


main :: IO ()
main = do
  IO.withFile "./test.csv"
              IO.ReadMode
              (\handle -> do
                  let producer = (PCsv.decode PCsv.NoHeader (PB.fromHandle handle))
                  headers <- P.head producer
                  putStrLn "Header"
                  putStrLn $ show headers
                  putStrLn $ "Rows"
                  runEffect ( producer>->
                              (showPipe) >->
                              P.stdoutLn)
               )

如果我们不先读取标题，我们可以毫无问题地读取整个 csv：

main :: IO ()
main = do
  IO.withFile "./test.csv"
              IO.ReadMode
              (\handle -> do
                  let producer = (PCsv.decode PCsv.NoHeader (PB.fromHandle handle))
                  putStrLn $ "Rows"
                  runEffect ( producer>->
                              (showPipe) >->
                              P.stdoutLn)
               )
4

1 回答 1

2

Pipes.Csv有处理标题的材料，但我认为这个问题确实是在寻找更复杂的使用Pipes.awaitor else Pipes.next。首先next：

>>> :t Pipes.next 
Pipes.next :: Monad m => Producer a m r -> m (Either r (a, Producer a m r))

next是检查生产者的基本方式。它有点像列表上的模式匹配。在列表中，两种可能性是[]and x:xs- 这里是Left ()and Right (headers, rows)。后一对是您正在寻找的。当然需要一个动作（在 中IO）来获得它：

main :: IO ()
main = do
  handle <- IO.openFile  "./test.csv" IO.ReadMode
  let producer :: Producer (V.Vector Text.Text) IO ()
      producer = PCsv.decode PCsv.NoHeader (PB.fromHandle handle)  >-> P.concat
  e <- next producer
  case e of
    Left () -> putStrLn "No lines!"
    Right (headers, rows) -> do
      putStrLn "Header"
      print headers
      putStrLn $ "Rows"
      runEffect ( rows >-> P.print)
  IO.hClose handle

由于Either这里的值会分散注意力，我消除了Left值 - 不解析的行 - 与P.concat

next不会在管道内部起作用，而是直接作用于Producer，它将其视为一种“有效列表”，最后有一个最终返回值。我们上面得到的特定效果当然可以通过 来实现await，它在管道中起作用。我可以用它来拦截管道中出现的第一个项目，基于它做一些 IO，然后转发剩余的元素：

main :: IO ()
main = do
  handle <- IO.openFile  "./grades.csv" IO.ReadMode
  let producer :: Producer (V.Vector Text.Text) IO ()
      producer = PCsv.decode PCsv.NoHeader (PB.fromHandle handle)  >-> P.concat
      handleHeader :: Pipe (V.Vector Text.Text) (V.Vector Text.Text) IO ()
      handleHeader = do
        headers <- await  -- intercept first value
        liftIO $ do       -- use it for IO
          putStrLn "Header"
          print headers
          putStrLn $ "Rows"
        cat               -- pass along all later values
  runEffect (producer >-> handleHeader >-> P.print)
  IO.hClose handle

不同之处在于如果producer为空，我将无法声明它，就像我No lines!在之前的程序中所做的那样。

请注意showPipe可以定义为的方式P.map show，或简单地定义为P.show（但使用您添加的专用类型。）

于 2016-12-20T19:34:50.910 回答