7

我刚刚在 clojure.spec 上看到了Rich 的演讲之一，我真的很想在我的项目中试一试。我正在编写一系列使用eclipse CDT 库解析 C 代码的工具，并且我想指定我的函数接受和发出 AST 对象。

我认为可以为一个函数编写一个非常基本的规范，该函数采用 AST 的根并发出所有树的叶子，如下所示：

(import '(org.eclipse.cdt.core.dom.ast IASTNode))
(require '[clojure.spec :as s])

(defn ast-node? [node] (instance? IASTNode node))
(s/def ::ast-node ast-node?)
(s/fdef leaves :args ::ast-node :ret (s/coll-of ::ast-node))

但是，当我尝试执行代码时(s/exercise leaves)，出现错误：

Unable to construct gen at: [] for:  
xxx.x$leaves@xxx  
#:clojure.spec{:path [], :form #function[xxx.xxx/leaves], :failure :no-gen}

如何为 Java 对象编写自定义生成器以完全规范和练习我的代码？

4

2 回答 2

14

您可以使用s/with-gen将自定义生成器附加到规范。您需要编写一个生成器来生成您需要的所有节点变体。您可能会发现为每个节点类型编写一个生成器然后将它们组合起来更容易，或者使用s/or或可能使用类似的东西s/multi-spec（这将使这对扩展开放）。

编写生成 Java 对象的生成器的示例如下：

(s/def ::date 
  (s/with-gen #(instance? java.util.Date %)
    (fn [] (gen/fmap #(java.util.Date. %) (s/gen pos-int?)))))

fmap 接受一个函数并将其应用于您提供给它的生成器的每个结果。如果你有一个带有多个值的构造函数的 Java 对象，你可以使用像(s/gen (s/tuple int? string? int?)).

于 2016-12-16T07:00:16.373 回答
2

为了完整起见，这是我在应用 Alex 的回答来指定“LiteralExpression”AST 节点后的代码：

(ns atom-finder.ast-spec
  (:import [org.eclipse.cdt.internal.core.dom.parser.cpp CPPASTLiteralExpression])
  (:require [clojure.spec :as s]
            [clojure.spec.gen :as gen]))

(def gen-literal-expression-args
 (gen/one-of
  [
   (gen/tuple (s/gen #{CPPASTLiteralExpression/lk_char_constant})
              (gen/char-ascii))
   (gen/tuple (s/gen #{CPPASTLiteralExpression/lk_float_constant})
              (gen/double))
   (gen/tuple (s/gen #{CPPASTLiteralExpression/lk_integer_constant})
              (s/gen (s/int-in -2147483648 2147483647)))
   (gen/tuple (s/gen #{CPPASTLiteralExpression/lk_string_literal})
              (gen/string))]))

(def gen-literal-expression
  (gen/fmap
   (fn [[type val]]
     (CPPASTLiteralExpression. type (.toCharArray (str val))))
   gen-literal-expression-args))

(s/def ::literal-expression
  (s/with-gen
    (partial instance? CPPASTLiteralExpression)
    (fn [] gen-literal-expression)))

(s/exercise :atom-finder.ast-spec/literal-expression 10
于 2016-12-22T02:37:46.240 回答