1

我正在使用 pegjs 定义允许定义新类型的语法。然后我如何识别它们定义之后的那些类型？我有一个定义内置类型的产品，例如

BuiltInType
  = "int"
  / "float"
  / "string"
  / TYPE_NAME

但是最后一个我该怎么办？在源代码中定义之前，我不知道哪些可能的字符串是类型名称。

在同时存在词法分析器和解析器的传统解析方式中，解析器会将类型名称添加到表中，并且词法分析器将使用该表来确定是否为特定令牌返回 TYPE_NAME 或 IDENTIFIER。但是 pegjs 没有这种分离。

4

1 回答 1

1

你是对的，如果不了解它的内部结构，你就不能（轻松地）动态修改 pegjs 生成的解析器。但是，您从标准 LALR 中失去的东西，是在整个解析器规则本身中散布 JavaScript 代码的过程中获得的。

为了实现您的目标，您需要识别新类型（在上下文中）并保留它们以供以后使用，如下所示：

{
  // predefined types
  const types = {'int':true, 'float':true, 'string':true}

  // variable storage
  const vars = {}
}

start = statement statement* {
  console.log(JSON.stringify({types:types,vars:vars}, null, 2))
}

statement
  = WS* typedef EOL
  / WS* vardef EOL

typedef "new type definition" // eg. 'define myNewType'
  = 'define' SP+ type:symbol {
    if(types[type]) {
      throw `attempted redefinition of: "${type}"`
    }
    types[type]=true
  }

// And then, when you need to recognize a type, something like:

vardef "variable declaration" // eg: 'let foo:myNewType=10'
  = 'let' SP+ name:symbol COLON type:symbol SP* value:decl_assign? {
   if(!types[type]) {
     throw `unknown type encountered: ${type}`
   }
   vars[name] = { name: name, type:type, value: value }
}

decl_assign "variable declaration assignment"
  = '=' SP* value:number {
    return value
  }

symbol = $( [a-zA-Z][a-zA-Z0-9]* )

number = $( ('+' / '-')? [1-9][0-9]* ( '.' [0-9]+ )? )

COLON = ':'
SP = [ \t]
WS = [ \t\n]
EOL = '\n'

其中，当被要求解析时：

define fooType
let bar:fooType = 1

将打印：

{
  "types": {
    "int": true,
    "float": true,
    "string": true,
    "fooType": true
  },
  "vars": {
    "bar": {
      "name": "bar",
      "type": "fooType",
      "value": "1"
    }
  }
}
于 2017-01-26T23:05:22.273 回答