1

我是 ActionScript 开发的新手，正在使用 FlashDevelop IDE。我一直在玩一些非常简单的事情，并且遇到了一个我似乎无法解决的问题。

我的应用程序编译并运行，一个监视单击事件的函数完美触发，当我将它传递给 trace() 时，我可以在控制台中看到该事件，但是监视 KeyboardEvent 的相同代码根本无法触发。

这是我的代码：

package GameTesting
{

    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;

    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.events.KeyboardEvent;

    [Frame(factoryClass="GameTesting.Preloader")]
    public class Main extends Sprite
    {

        public function Main():void
        {
            if (stage) {
                init();
            } else {
                addEventListener(Event.ADDED_TO_STAGE, init);
            }
        }

        private function init(e:Event = null):void
        {
            removeEventListener(Event.ADDED_TO_STAGE,init);

            addEventListener(MouseEvent.CLICK, onClickEvent);
            addEventListener(KeyboardEvent.KEY_DOWN, onKeyDownEvent);
        }

        private function onKeyDownEvent(e:KeyboardEvent):void
        {
            trace(e);
        }

        private function onClickEvent(e:MouseEvent):void
        {
            trace(e);
        }

    }

}

MouseEvent trace() 每次都按预期触发，但 KeyboardEvent 永远不会触发，无论我按什么键。有任何想法吗？

4

3 回答 3

6

您需要将侦听器添加到舞台：

private function init(e:Event = null):void
{
    removeEventListener(Event.ADDED_TO_STAGE,init);

    stage.addEventListener(MouseEvent.CLICK, onClickEvent);
    stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDownEvent);
}
于 2010-11-04T20:33:09.890 回答
3

您可能需要确保监听事件的影片剪辑具有焦点。如果您的游戏有某种菜单或开始屏幕，您可以单击按钮开始，即使已从舞台上移除该影片剪辑也可以保持焦点。

这是一篇很好的文章，更详细地解释了这一点： 舞台上的键盘事件不起作用......？

于 2012-09-25T17:31:40.103 回答
1

如果您在 Flash IDE 中（至少对于 CS4），您还需要在调试 (Ctrl+Shift+Enter) 或测试 (Ctrl+Enter) fla 时禁用键盘快捷键。

在影片窗口中，选择“控制”->“禁用键盘快捷键”。这将停止 Flash IDE 接收键盘输入，并允许调试/测试窗口取而代之。

于 2010-11-05T01:03:06.060 回答