3

我正在尝试制作一个在一个大型阵列上进行大量更新的程序，但只评估几次。我希望计算尽可能地懒惰，但我找不到哪种数组表示适合我的情况。具体来说，我希望我的数组：

  • 有固定大小
  • 恒定时间访问
  • 更新 O(n) 中的 n 个元素
  • 懒惰评估

如何接近这些要求？作为一个子问题：是否有专门针对此用例的库？

编辑：

也许我的问题不够具体，所以我会尝试更多地解释我的情况。

我试图表示各种尺寸的图像，这些图像可以相对较小（大约 1200x800），也可以比它大得多（至少 8000x8000）。此外，一个图像会有很多层，这意味着如果我想在屏幕上绘制图像，帧缓冲图像会有很多更新。我想如果我可以利用 haskell 的惰性求值特性，我将能够只在帧缓冲区上写入一次，而不是在每次更新时覆盖相同的像素。

我知道在 haskell 中表示数组的几个选项，但所有这些似乎都不适合我的情况。例如：

  • Data.Seq, Data.IntTrie : 不能在固定时间内访问
  • Data.Vector, Data.Array : 更新 n 个元素花费的时间超过 O(n)
  • 未装箱的变体：不是懒惰评估的（我猜？）

在这种情况下我应该采取什么方法？

4

1 回答 1

4

要考虑的一个库是repa. 其中的一个关键思想repa是该Array类型在其底层表示上被参数化。其中一个示例是

  • D“不真实”的数组的延迟表示——它们只是按需计算元素；
  • U未装箱数据的未装箱矢量表示
  • 盒装数据的盒装矢量表示V（仅在您无法创建Unbox数据实例时使用）
  • 对外部缓冲区的引用F，如果您想写入一些外部位图图形缓冲区，则特别有用

当你编译你的代码时，延迟的数组会被优化掉。不用说，未装箱的数组可以O(1)访问。对于您的情况，您可能只会使用形状DIM2数组（二维数组）。

出于演示目的，这里有一个程序，它执行的操作与您想要的类似：它接收位图图层列表及其偏移量，以及背景位图。然后，它将这些图层绘制在位图背景之上。这取决于repa-io将图像加载到repa数组中。

import Data.Array.Repa.IO.BMP
import Data.Array.Repa.Shape
import Data.Array.Repa
import Data.Word

-- This is our internal representation of a bitmap
type Image s = Array s DIM2 (Word8, Word8, Word8)
data Layer s = Layer { image :: Image s, offset :: (Int, Int) }

drawLayersOnBg :: Image U -> [Layer U] -> Image D
drawLayersOnBg background layers = foldl (\bg (Layer im (x,y)) -> overlay bg (ix2 y x) im) (delay background) layers
  where
    overlay :: Image D -> DIM2 -> Image U -> Image D
    overlay bg off ov = backpermuteDft bg
                                       (\i -> let i' = i `subDim` off
                                                 in if extent ov `inShape` I'
                                                      then Just i'
                                                      else Nothing)
                                       ov

    subDim :: DIM2 -> DIM2 -> DIM2
    subDim (Z :. y :. x) (Z :. dy :. dx) = ix2 (y - dy) (x - dx)

main = do
  Right bg <- readImageFromBMP "background.bmp"
  Right l1 <- readImageFromBMP "layer1.bmp"
  Right l2 <- readImageFromBMP "layer2.bmp"
  Right l3 <- readImageFromBMP "layer3.bmp"

  out <- computeP $ drawLayersOnBg bg [ Layer l1 (200,100) , Layer l2 (100, 200), Layer l3 (-300,400) ]
  writeImageToBMP "out.bmp" out

使用来自互联网的一些随机位图，我将其作为输出：

输出

如果我愿意，我什fromForeignPtr至可以直接从某个外部内存缓冲区读取位图，computeIntoP而不是computeP将位图输出直接写入某个外部内存缓冲区（没有中间分配）。如果你需要高性能，这些特别有趣。

于 2016-12-04T09:24:04.423 回答