6

我想削弱Sub::Quote生成的代码中捕获的变量。例如，这是未引用的替代方案：

use 5.10.0;
use Scalar::Util qw[ weaken ];
{
  my $s = 'foo';
  my $x = sub { say $s };
  weaken( my $y = $x );

  my $bar = sub { &$y };
  &$bar;
  $x = undef;
  &$bar
}

和输出：

foo
Can't use an undefined value as a subroutine reference [...]

这是我的 Sub::Quote 尝试：

use 5.10.0;
use Sub::Quote;
use Scalar::Util qw[ weaken ];
{
  my $s = 'foo';
  my $x = sub { say $s };
  weaken( my $y = $x );

  my $bar = quote_sub( '&$y', { '$y' => \$y } );
  &$bar;
  $x = undef;
  &$bar;
}

和输出：

foo
foo

显然被俘$y并没有被削弱。有没有办法改变生成的代码来削弱捕获的变量？

文档稀少，Sub::Quote实现复杂；我相当相信当前代码不可能做到这一点，但我很乐意被证明是错误的。

4

1 回答 1

4 
my $bar = quote_sub( '&$y', { '$y' => \$y } );

大致相同

my $bar = eval(q{ my $y = $y; sub { &$y } });

（它做得更多，但这些位与这个问题无关）。如您所见，这创建了对 sub [1]的新强引用。

作为一种解决方法，您可以添加一个间接层：

my $bar = eval(q{ my $y_ref = \$y; sub { &{ $$y_ref } } });

这可以通过使用来实现：

my $bar = quote_sub( '&{$$y_ref}', { '$y_ref' => \\$y } );

如果$ySub::Quote 创建的 是您的$y. 这可以使用 Data::Alias 或 5.22 中引入的实验特性来实现。

这可以使用以下方法来证明：

{
  package Sub::Quote;

  my $sub = sub {
    my ($from, $captures, $indent) = @_;
    join(
      '',
      "use feature qw( refaliasing );\n",
      "no warnings qw( experimental::refaliasing );\n",
      map {
        /^([\@\%\$])/
          or croak "capture key should start with \@, \% or \$: $_";
        (' ' x $indent).qq{\\my ${_} = \\${1}{${from}->{${\quotify $_}}};\n};
      } keys %$captures
    )
  };

  no warnings qw( redefine );
  *capture_unroll = $sub;
}


my $bar = quote_sub( '&$y', { '$y' => \$y } );

您可以与模块的维护者讨论添加一个会导致使用别名的选项。

  1. 当您创建（强或弱）引用的副本时，它就是强引用。
于 2016-11-25T19:48:59.817 回答