4

我正在使用程序集 8086emu，我需要一个用于 8 个数字的数字生成器。
我尝试使用@johnfound 的这段代码：

RANDGEN:         ; generate a rand no using the system time

RANDSTART:
   MOV AH, 00h  ; interrupts to get system time        
   INT 1AH      ; CX:DX now hold number of clock ticks since midnight      

   mov  ax, dx
   xor  dx, dx
   mov  cx, 10    
   div  cx       ; here dx contains the remainder of the division - from 0 to 9

   add  dl, '0'  ; to ascii from '0' to '9'
   mov ah, 2h   ; call interrupt to display a value in DL
   int 21h    
RET

但仅当您生成一个数字时才有用。重复调用得到相同的数字，因为该时钟每秒仅滴答 18.2 次。

我试图创建伪随机函数，但我对汇编很陌生，但我没有成功。我想知道是否有办法Math.random()在emu8086中做类似于java的函数。

4

2 回答 2

7

一个简单的伪随机数生成器将当前数字乘以 25173，然后将 13849 加到它上面。该值现在成为新的随机数。
如果您像以前一样从系统计时器开始（这称为播种随机数生成器），这一系列数字对于简单任务来说将是足够随机的！

MOV     AH, 00h   ; interrupt to get system timer in CX:DX 
INT     1AH
mov     [PRN], dx
call    CalcNew   ; -> AX is a random number
xor     dx, dx
mov     cx, 10    
div     cx        ; here dx contains the remainder - from 0 to 9
add     dl, '0'   ; to ascii from '0' to '9'
mov     ah, 02h   ; call interrupt to display a value in DL
int     21h    
call    CalcNew   ; -> AX is another random number
...
ret

; ----------------
; inputs: none  (modifies PRN seed variable)
; clobbers: DX.  returns: AX = next random number
CalcNew:
    mov     ax, 25173          ; LCG Multiplier
    mul     word ptr [PRN]     ; DX:AX = LCG multiplier * seed
    add     ax, 13849          ; Add LCG increment value
    ; Modulo 65536, AX = (multiplier*seed+increment) mod 65536
    mov     [PRN], ax          ; Update seed = return value
    ret

这实现了一个具有 2 次幂模数的线性同余生成器 (LCG)。 %65536发生是免费的，因为乘积 + 增量的低 16 位在 AX 中，而高位不在。

于 2016-11-20T21:36:12.493 回答
2

好主意，有缺陷的执行。上面显示的代码会生成一个可预测的偶-奇-偶-奇-偶-奇等模式。这不是很“随机”。维基百科警告说，线性同余生成器的高位往往非常随机，但低位则不然。解决方法是在保存种子后立即插入 SHR AX,5。种子仍然翻转偶-奇-偶-奇，但从种子中获得的随机数忽略了五个最低有效位。CalcNew 的结尾应该是这样的：

    mov     [PRN], ax          ; Update seed
    shr     ax,5               ; Discard 5 bits
    ret

它不必正好是五位。我选择了五个，因为少于五个还不够随机，但超过五个会削弱您选择所需随机数的能力。AX 只有 16 位；在你丢弃其中五个之后，你会得到一个介于 0 和 2047 之间的随机数，这对于下一步除以某个数 n 并取余数非常有用。当 n 为 10 时，2047 就足够了。但是您的 n 可能会更大，具体取决于应用程序。如果你需要一个随机的 ascii 字符，你将除以 96。如果你放弃了，比如说，七位而​​不是五位，你会有一个从 0 到 511 的随机 AX，你将除以 96 到得到一个余数。这会扭曲您的结果，因为较低的余数会比较高的余数更频繁地发生。所以五位是一个很好的折衷方案，当你'

于 2020-04-23T17:12:03.447 回答