1

我有一个在这里运行良好的代码：

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;



        my %graph =(
            F => ['B','C','E'],
            A => ['B','C'],
            D => ['B'],
            C => ['A','E','F'],
            E => ['C','F'],
            B => ['A','E','F']
        );

        sub findPaths {
            my( $seen,  $start, $end ) = @_;

            return [[$end]] if $start eq $end;

            $seen->{ $start } = 1;
            my @paths;
            for my $node ( @{ $graph{ $start } } ) {
                my %seen = %{$seen};
                next if exists $seen{ $node };
                push @paths, [ $start, @$_ ] for @{ findPaths( \%seen, $node, $end ) };
            }
            return \@paths;
        }


            my $start = "B";
            my $end   = "E";
        print "@$_\n" for @{ findPaths( {}, $start, $end ) };

我想要做的是生成一个更通用的子程序，以便它只\%graph, $start,$end作为输入并返回最终数组。

我试图这样做，但它没有编译。

sub findPathsAll {

    my ($graph,$start,$end) = @_;

    my $findPaths_sub;
        $findPaths_sub {
            my( $seen) = @_;

            return [[$end]] if $start eq $end;

            $seen->{ $start } = 1;
            my @paths;
            for my $node ( @{ $graph{ $start } } ) {
                my %seen = %{$seen};
                next if exists $seen{ $node };
                push @paths, [ $start, @$_ ] for @{ &$findPaths_sub( \%seen, $node, $end ) };
            }
            return \@paths;
        }


    my @all;
    push @all,@$_ for @{ &$findPaths_sub( {}, $start, $end ) };
    return @all;
}

正确的方法是什么？

4

2 回答 2

4

我无法弄清楚你想要findPathsAll返回什么，所以这可能不是你想要的。无论如何，这是findPaths一个词法递归代码引用的翻译：

use Scalar::Util 'weaken';

sub findPathsAll {
  my ($graph,$start,$end) = @_;

  my $findPaths_sub;
  my $strongRef = $findPaths_sub = sub {
    my( $seen, $start, $end ) = @_;

    return [[$end]] if $start eq $end;

    $seen->{ $start } = 1;
    my @paths;
    for my $node ( @{ $graph->{ $start } } ) {
      my %seen = %{$seen};
      next if exists $seen{ $node };
      push @paths, [ $start, @$_ ]
          for @{ $findPaths_sub->( \%seen, $node, $end ) };
    }
    return \@paths;
  };

  weaken($findPaths_sub);       # Prevent memory leak

  my @all;
  push @all,@$_ for @{ $findPaths_sub->( {}, $start, $end ) };
  return @all;

  ## The above turns all the paths into one big list of nodes.
  ## I think maybe you meant this:
  #    return @{ $findPaths_sub->( {}, $start, $end ) };
  ## which would return a list of arrayrefs, one for each path.
}

一些注意事项：

你这样声明一个coderef：

$var = sub { ... };

注意赋值运算符和结尾的分号。如果您希望 coderef 是递归的，您必须已经声明了$var. （如果你说my $var = sub { ... };，新变量直到创建 sub之后才存在，所以它不能引用$var。）

你这样称呼它：

$var->(arg1, arg2, ...);

（还有其他可用的语法，但我认为这是首选。）

在我发布的第一个版本中存在细微的内存泄漏。Perl 使用引用计数垃圾收集器，这意味着它不能删除自引用数据结构。由于 coderef$findPaths_sub捕获了对自身的引用，因此永远不会清理它（直到程序退出）。我现在使用Scalar::Util中的weaken函数（正如singfish 在他的博客条目中提到的那样）来避免这种情况。 $strongRef仅用于防止 coderef 在我们完成之前被垃圾收集。

于 2010-11-01T07:09:30.333 回答
1

前几天我在博客上讨论了这个问题。

于 2010-11-01T09:35:23.310 回答