4

我正在尝试创建一个函数，该函数返回一个可以在 FROM 子句中使用的对象。根据对 oracle 文档的研究，我发现我需要一个 PIPELINED 函数。

我有这个代码：

CREATE TYPE type_struct AS OBJECT
(
    i NUMBER
);

CREATE TYPE tp_struct AS TABLE OF type_struct;

CREATE OR REPLACE FUNCTION gen_nums (na NUMBER, nb NUMBER)
RETURN tp_struct PIPELINED
IS
    rec type_struct;
    counter NUMBER;
BEGIN
    counter := na;

    WHILE (counter <= nb)
    LOOP
        SELECT counter
        INTO rec
        FROM dual;

        counter := counter + 1;

        PIPE ROW (rec);
    END LOOP;

    RETURN;
END gen_nums;
/

预期的结果是一个包含从“na”到“nb”记录的表，两者都包括在内。

但是在编译函数时出现此错误：

ORA 00932 不一致的数据类型预期 udt 得到了编号

4

2 回答 2

6

ORA 00932 inconsistent datatypes expected udt got number

你得到这个是因为你的代码为输出类型分配了一个标量。您需要强制转换变量以匹配分配目标。所以：

   SELECT type_struct(counter)
    INTO rec
    FROM dual;

您不一定需要流水线功能。我们可以table()与任何返回集合的函数一起使用。

这是一个更简单的实现，它只需要一个 UDT。

CREATE TYPE tp_numbers AS TABLE OF number;
/
CREATE OR REPLACE FUNCTION gen_nums (na NUMBER, nb NUMBER)
RETURN tp_numbers 
IS
    return_value tp_numbers ;
BEGIN
    SELECT (na + level) - 1 
    bulk collect    INTO return_value  
    FROM dual
    connect by level <= nb;

    RETURN return_value ;
END gen_nums;
/
于 2016-11-16T11:30:58.290 回答
0 
CREATE OR REPLACE FUNCTION gen_nums (na NUMBER, nb NUMBER)
RETURN sys.DBMS_DEBUG_VC2COLL PIPELINED --sys.DBMS_DEBUG_VC2COLL an oracle provided collection type.
IS
    counter NUMBER;
BEGIN
    counter := na;
    WHILE (counter <= nb)
    LOOP
        PIPE ROW (counter);
        counter := counter + 1;
    END LOOP;
    RETURN;
END gen_nums;
于 2016-11-16T11:17:59.803 回答