2

因此，Grails 已经设置了由连接池支持的数据源。有没有办法利用它们DBAppender在 Logback 中使用，这样我就不必创建单独的并行数据源/连接池？

logback.groovy对 Grails 来说有点外部，所以它不接受 Spring 自动装配，并且其他类似的技巧grails.util.Holders.findApplication()似乎不起作用。

4

1 回答 1

3

哇，这是一件苦差事。坦率地说，我对 Logback 有点失望。Logback 创建它自己的 Spring ApplicationContext。所以我们有两个不同的上下文。啊。此外，Logback 用于在 Groovy 中配置 Spring 的 DSL 与 Grails 不同，这当然也无济于事。

由于 Logback 在 Grails 完全启动之前就被启动了，我们需要告诉 Logback 创建一些虚拟的 appender，它们只会存储日志消息，直到我们从 Grails 中启动 appender。我们使用 Spring 的 logback 扩展来执行此操作。

构建.gradle：

compile 'org.logback-extensions:logback-ext-spring:0.1.4'

logback.groovy：

import ch.qos.logback.ext.spring.DelegatingLogbackAppender

appender('DB', DelegatingLogbackAppender)
appender('STDOUT', DelegatingLogbackAppender)

资源.groovy：

import ch.qos.logback.ext.spring.ApplicationContextHolder
import ch.qos.logback.classic.encoder.PatternLayoutEncoder
import ch.qos.logback.classic.db.DBAppender
import ch.qos.logback.core.ConsoleAppender
import ch.qos.logback.core.db.DataSourceConnectionSource
import org.slf4j.LoggerFactory

beans = {
    applicationContextHolder(ApplicationContextHolder)

    loggerContext(LoggerFactory) { bean ->
        bean.factoryMethod = "getILoggerFactory"
    }

    patternLayoutEncoder(PatternLayoutEncoder) { bean ->
        bean.initMethod = 'start'
        bean.destroyMethod = 'stop'

        context = ref(loggerContext)
        pattern = "%level %logger - %msg%n"
    }

   STDOUT(ConsoleAppender) { bean ->
        bean.initMethod = 'start'
        bean.destroyMethod = 'stop'
        context = ref(loggerContext)
        encoder = ref(patternLayoutEncoder)
    }

    connectionSource(DataSourceConnectionSource) { bean ->
        bean.initMethod = 'start'
        bean.destroyMethod = 'stop'
        context = ref(loggerContext)
        dataSource = ref(dataSource)
    }

    DB(DBAppender) { bean ->
        bean.initMethod = 'start'
        bean.destroyMethod = 'stop'
        context = ref(loggerContext)
        connectionSource = ref(connectionSource)
    }
}

在您在或中配置的数据源ref(dataSource)的DataSourceConnectionSource引用中。application.ymlapplication.groovy

假设您有多个数据源（或者甚至一个为 logback 配置的称为dataSources.logging. 在这种情况下，bean 引用将是dataSource_logging。在这种情况下，默认数据源（称为dataSources.dataSourcebean 引用只是dataSource. 花了我一段时间才弄清楚。

总而言之，我怀念使用 Grails DSL 从 Grails 配置文件中配置Log4j的日子。我知道将日志记录与 Grails 分开对 Graeme 和 Grails 团队来说意味着少了一件事情，但这是我认为很常见的事情的主要 PITA。¯\_(ツ)_/¯

于 2016-11-10T17:04:31.777 回答