1

我想用一个依赖于旧状态的函数来修改我的状态，但也引入了一些随机性。我的功能f如下所示：

f :: State -> Eff (random :: RANDOM) State

Eff我想我的状态应该是纯的，除了 using 之外，我不知道如何摆脱unsafePerformEff，所以我这样做了：

eval :: Query ~> H.ComponentDSL State Query g
eval (Tick next) = do
  H.modify (unsafePerformEff <<< f)
  pure next

这行得通，但必须有另一种更安全的方法。我已经将随机效果添加到我的主要功能中：

main :: Eff (H.HalogenEffects (random :: RANDOM)) Unit

但是应该怎么eval看？也许modify在这里不起作用，还有另一种更新状态的方法？

Purescript Halogen，副作用（随机数）对我不起作用，因为f取决于旧状态。

4

1 回答 1

1

modify本身并不能让您执行有效的更新，但是是的，您可以在之后使用getthen modify（或set）来执行此操作。改编自另一个随机示例：

module Main where

import Prelude
import Control.Monad.Aff (Aff)
import Control.Monad.Eff (Eff)
import Control.Monad.Eff.Random (randomInt, RANDOM)
import Halogen as H
import Halogen.HTML.Events.Indexed as HE
import Halogen.HTML.Indexed as HH
import Halogen.Util (runHalogenAff, awaitBody)

type State = { n :: Int }

initialState :: State
initialState = { n: 3 }

data Query a = NewRandom a

ui :: forall eff. H.Component { n :: Int } Query (Aff (random :: RANDOM | eff))
ui =
  H.component { render, eval }
    where
    render :: State -> H.ComponentHTML Query
    render state =
        HH.button
            [ HE.onClick $ HE.input_ NewRandom ]
            [ HH.text $ show state.n ]


    eval :: Query ~> H.ComponentDSL State Query (Aff (random :: RANDOM | eff))
    eval (NewRandom next) = do
      state <- H.get
      nextState <- H.fromEff (nextRandom state)
      H.set nextState
      pure next

    nextRandom :: State -> Eff (random :: RANDOM | eff) State
    nextRandom { n } = do
      nextN <- randomInt (n + 1) (n + 10)
      pure { n: nextN }

main :: forall eff. Eff (H.HalogenEffects (random :: RANDOM | eff)) Unit
main =
    runHalogenAff do
    body <- awaitBody
    H.runUI ui initialState body

可能导致类型错误的是这种类型签名：

f :: State -> Eff (random :: RANDOM) State

效果行已关闭，这意味着它不会与任何其他行统一，您可能想要这个：

f :: forall eff. State -> Eff (random :: RANDOM | eff) State
于 2016-10-25T23:18:37.377 回答