erlang - Erlang Eunit 测试套件的常用设置和拆卸方法

Question

我正在尝试检查我在 MongoDB 中定义的所有索引是否正在被我的应用程序使用，并且没有额外的索引。我有一个实用程序可以为单个Eunit测试套件执行此操作。但是，我的一些组件有多个Eunit测试套件，我想知道是否有一种方法可以在调用任何测试套件之前运行通用代码，然后在所有测试套件完成后运行通用拆卸代码。我rebar用来调用Eunit.

提前致谢。

Answer 1

只要用于测试表示的 eunit 文档解释，测试集可以是深度列表。下面是一个示例模块，显示了外部setup夹具的使用，其测试是生成器，每个都提供一个内部setup夹具。内部setup夹具对应于您现有的测试套件，每个测试套件都有自己的设置和清理功能。外部setup夹具为内部套件提供通用设置和清理。

-module(t).
-compile(export_all).

-include_lib("eunit/include/eunit.hrl").

top_setup() ->
    ?debugMsg("top setup").

top_cleanup(_) ->
    ?debugMsg("top cleanup").

test_t1() ->
    {setup,
     fun() -> ?debugMsg("t1 setup") end,
     fun(_) -> ?debugMsg("t1 cleanup") end,
     [fun() -> ?debugMsg("t1 test 1") end,
      fun() -> ?debugMsg("t1 test 2") end,
      fun() -> ?debugMsg("t1 test 3") end]}.

test_t2() ->
    {setup,
     fun() -> ?debugMsg("t2 setup") end,
     fun(_) -> ?debugMsg("t2 cleanup") end,
     [fun() -> ?debugMsg("t2 test 1") end,
      fun() -> ?debugMsg("t2 test 2") end,
      fun() -> ?debugMsg("t2 test 3") end]}.

t_test_() ->
    {setup,
     fun top_setup/0,
     fun top_cleanup/1,
     [{generator, fun test_t1/0},
      {generator, fun test_t2/0}]}.

编译这个模块，然后从 Erlang shell 运行它会产生预期的输出：

1> c(t).
{ok,t}
2> eunit:test(t).
/tmp/t.erl:7:<0.291.0>: top setup
/tmp/t.erl:14:<0.293.0>: t1 setup
/tmp/t.erl:16:<0.295.0>: t1 test 1
/tmp/t.erl:17:<0.295.0>: t1 test 2
/tmp/t.erl:18:<0.295.0>: t1 test 3
/tmp/t.erl:15:<0.293.0>: t1 cleanup
/tmp/t.erl:22:<0.293.0>: t2 setup
/tmp/t.erl:24:<0.300.0>: t2 test 1
/tmp/t.erl:25:<0.300.0>: t2 test 2
/tmp/t.erl:26:<0.300.0>: t2 test 3
/tmp/t.erl:23:<0.293.0>: t2 cleanup
/tmp/t.erl:10:<0.291.0>: top cleanup
  All 6 tests passed.
ok

通用设置首先运行，然后每个套件由其自己的设置和清理包围运行，然后通用清理最后运行。

Answer 2

您可以查看固定装置，尤其是固定装置setup： http: //erlang.org/doc/apps/eunit/chapter.html#Fixtures