1

我用 StringGrid 绿色填充单元格

procedure TForm1.StringGridDrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
begin

StringGrid.Canvas.Brush.Color := clGreen;
StringGrid.Canvas.FillRect(Rect);

StringGrid.Canvas.TextOut(Rect.Left + 2, Rect.Top + 2, AGrid.Cells[ACol, ARow]);

end;

我的 StringGrid 有黑色。我想填充单元格透明颜色（例如 50%）。

我怎样才能做到这一点？

我应该画矩形？或者我应该创建位图并放入单元格？

你能帮助我吗？：）

意思是这样的效果： 在此处输入图像描述

4

1 回答 1

7

受这篇文章的启发，我首先在背景中创建了TStringGrid一个图像。然后我为选定的单元格添加了一个透明的颜色WinApi.Windows.AlphaBlend()，对于固定的单元格也是如此。最终结果是这样的：

在此处输入图像描述

透明的“选定”颜色作为 1 像素位图完成：

type
  TStringGrid = class(Vcl.Grids.TStringGrid)
  private
    FBackG: TBitmap;
    FForeG: TBitmap;
  ...

procedure TForm5.Button1Click(Sender: TObject);
begin
  sg.FForeG.Free;
  sg.FForeG := TBitmap.Create;
  sg.FForeG.SetSize(1, 1);
  sg.FForeG.PixelFormat := pf32bit;
  sg.FForeG.Canvas.Pixels[0, 0] := $00FF00;  // BGR
end;

并且位图应用于事件中的“选定”单元格（ gdSelected in State）OnDrawCell

procedure TForm5.sgDrawCell(Sender: TObject; ACol, ARow: Integer; Rect: TRect;
  State: TGridDrawState);
var
  sg: TStringGrid;
  r: TRect;
  success:boolean;
begin
  if not (Sender is TStringGrid) then Exit;
  sg := Sender as TStringGrid;

  r := Rect;
  r.Left := r.Left-4; // Might not be needed, depending on Delphi version?

  // Clear the cell
  sg.Canvas.Brush.Color := clBlack;
  sg.Canvas.FillRect(r);

  // Copy background to cell
  BitBlt(sg.Canvas.Handle,
    r.Left, r.Top, r.Right - r.Left, r.Bottom - r.Top,
    sg.FBackG.Canvas.Handle, r.Left, r.Top, SRCCOPY);

    // Draw fixed column or row cell(s)
  if gdFixed in State then
  begin
    success := Winapi.Windows.AlphaBlend(sg.Canvas.Handle,
      r.Left, r.Top, r.Right - r.Left, r.Bottom - r.Top,
      sg.FHeadG.Canvas.Handle, 0, 0, 1, 23, BlendFunc);
  end;

  // Draw selected cell(s)
  if gdSelected in State then
  begin
    success := Winapi.Windows.AlphaBlend(sg.Canvas.Handle,
      r.Left, r.Top, r.Right - r.Left, r.Bottom - r.Top,
      sg.FForeG.Canvas.Handle, 0, 0, 1, 1, BlendFunc);
  end;

  // Draw the text
  r := Rect;
  sg.Canvas.Brush.Style := bsClear;
  DrawText(sg.Canvas.Handle, sg.Cells[ACol, ARow],
    length(sg.Cells[ACol, ARow]), r,
    DT_SINGLELINE or DT_VCENTER or DT_END_ELLIPSIS);
end;

该BlendFunc: _BLENDFUNCTION;结构可以在TStringGrid子类或其他可访问的地方声明，我在表单中声明它并在表单OnCreate事件中对其进行初始化：

  BlendFunc.BlendOp := AC_SRC_OVER;
  BlendFunc.BlendFlags := 0;
  BlendFunc.SourceConstantAlpha := 128;  // This determines opacity
  BlendFunc.AlphaFormat := AC_SRC_ALPHA;

现在，您可能会问，1 像素位图是如何工作的，答案在文档中AlphaBlend()：

如果源矩形和目标矩形的大小不同，则源位图被拉伸以匹配目标矩形。

这很有用，因为单元格矩形的大小通常不同。

标题行和列在OnDrawCellon 条件下类似地绘制if gdFixed in State，这里使用了另一个位图。它是我在图形绘图程序中单独制作的 1 像素宽和 23 像素高的位图。

在此处输入图像描述

是的！上面的小东西是图像。

于 2016-10-14T21:21:11.823 回答