struct - 如何在 Racket 中定义递归结构？

Question

我试图在无类型 Racket 中模仿 OCaml 中的递归类型，但我似乎找不到关于定义递归结构的文档。我将如何进行映射：

type example =
| Red
| Blue of example
| Yellow of example * example;;

进入球拍中的东西？

我尝试了以下方法：

(struct Red ())
(struct Blue (e1))
(struct Yellow (e1 e2))
(struct example/c
    (or/c (Red)
          (Blue example/c)
          (Yellow example/c example/c)))

但是，当我将 example/c 放入合同时，它并没有按预期工作，因为它声称这是一个程序。有什么帮助吗？

Answer 1

我已经改变了这个例子。这是一个变量e具有 contract的示例example/c。

#lang racket

(struct Red     ()      #:transparent)
(struct Blue    (e1)    #:transparent)
(struct Yellow  (e1 e2) #:transparent)

(define example/c
  (flat-murec-contract ([red/c     (struct/c Red)]
                        [blue/c    (struct/c Blue   example/c)]
                        [yellow/c  (struct/c Yellow example/c example/c)]
                        [example/c (or/c red/c blue/c yellow/c)])
                       example/c))


(define r (Red))
(define b (Blue r))
(define y (Yellow r b))
(define e y)

(provide (contract-out [e example/c]))

(match e
  [(Red)          (list "Red")]
  [(Blue   e1)    (list "Blue" e1)]
  [(Yellow e1 e2) (list "Yellow" e1 e2)]
  [else           "huh"])

如果你改变，比如说，(Yellow r b)那么(Yellow r 42)你会得到一个错误。