2

我正在使用Reflex.Dom 库，它定义了一组用于创建 HTML DOM 元素的函数

  • el创建一个元素
  • el'创建并返回一个元素
  • elAttr创建具有给定属性的元素
  • elAttr'创建并返回具有给定属性的元素
  • ETC

我正在制作自己的小部件库，我不想为每个小部件定义所有这些变体。所以我写了一个类型类，它使用相同的名称，但是根据彼此定义所有函数，每个实例中只定义一个：

{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE OverloadedStrings #-}

module ElMaker where

import Data.Map (Map)
import qualified Data.Map as Map
import qualified Reflex.Dom as D

-- el: type of element to create
-- input: input parameter
-- output: return value
class (D.MonadWidget t m) => ElMaker t m el input output where
  el :: el -> input -> m output
  el e = elAttr e Map.empty

  elAttr :: el -> Map Text Text -> input -> m output
  elAttr e attrs input = snd <$> elAttr' e attrs input

  el' :: el -> input -> m (D.El t, output)
  el' e = elAttr' e Map.empty

  -- This is the only one to implement, yay!
  elAttr' :: el -> Map Text Text -> input -> m (D.El t, output)

我创建了一个使用原始实例elAttr'来测试它的实例。有效：

import Data.Text (Text)
import qualified Reflex.Dom as D

instance (D.MonadWidget t m) => ElMaker t m Text (m output) output where
  elAttr' = D.elAttr'

然后我创建了一个Button小部件实例，它在单击按钮时返回一个事件。有效：

data Button = Button
instance (MonadWidget t m) => ElMaker t m Button (m input) (Event t ()) where
  elAttr' _ attrs contents = do
    (e, _) <- D.el' "button" contents
    return $ (e, D.domEvent D.Click e)

我希望能够编写小部件，所以我尝试重写Button实例以使用Text实例ElMaker来创建元素。但它无法编译：

data Button = Button
instance (MonadWidget t m) => ElMaker t m Button (m input) (Event t ()) where
  elAttr' _ attrs contents = do
    (e, _) <- el' ("button" :: Text) contents
    return $ (e, D.domEvent D.Click e)

编译器输出：

MDL.hs:119:15: error:
    • Could not deduce (ElMaker t m Text (m input) output0)
        arising from a use of ‘el'’
      from the context: MonadWidget t m
        bound by the instance declaration at MDL.hs:116:10-71
      The type variable ‘output0’ is ambiguous
      Relevant bindings include
        contents :: m input (bound at MDL.hs:117:19)
        elAttr' :: Button
                   -> Map.Map Text Text -> m input -> m (D.El t, Event t ())
          (bound at MDL.hs:117:3)
      These potential instance exist:
        instance MonadWidget t m => ElMaker t m Text (m output) output
          -- Defined in ‘ElMaker’
    • In a stmt of a 'do' block:
        (e, _) <- el' ("button" :: Text) contents
      In the expression:
        do { (e, _) <- el' ("button" :: Text) contents;
             return $ (e, D.domEvent D.Click e) }
      In an equation for ‘elAttr'’:
          elAttr' _ attrs contents
            = do { (e, _) <- el' ("button" :: Text) contents;
                   return $ (e, D.domEvent D.Click e) }

我认为这是因为该函数没有对限制其类型的值做任何事情，并且编译器确实希望它具有具体类型。但是这个类型类并不关心那个类型参数的值是什么。有什么办法可以编译这个吗？

4

1 回答 1

5

=>您可能想要做的（这是您经常想要做的事情；它正在成为一个常见问题解答）是用左侧的等式约束替换右侧的构造函数。

{-# LANGUAGE GADTs #-}

instance (D.MonadWidget t m, input ~ m output)
   => ElMaker t m Text input output where ...

instance (D.MonadWidget t m, input' ~ m input, output ~ Event t ())
   => ElMaker t m Button input' output where ...

一旦你知道你正在构建Text或Button，你想提交到一个特定的实例，然后提交到具有特定形状的某些类参数。将它们放在实例约束中可以让您做到这一点。

对于这里的特殊情况，一旦您知道您正在处理Text，您就知道要使用哪个实例，并且可以output通过匹配来计算input。您希望 GHC 知道这一点，而不是想知道其他Text实例是否会有不同的输入/输出关系。

注意：通常最好是决定其他人最后的关键类参数。所以我会做el的最后一个参数ElMaker。这有利于新类型的推导，也是常规的。

于 2016-10-08T20:35:57.373 回答