9

我想使用 cython 加速以下代码：

class A(object):
    cdef fun(self):
        return 3


class B(object):
    cdef fun(self):
        return 2

def test():
    cdef int x, y, i, s = 0
    a = [ [A(), B()], [B(), A()]]
    for i in xrange(1000):
        for x in xrange(2):
            for y in xrange(2):
                s += a[x][y].fun()
    return s

唯一想到的是这样的：

def test():
    cdef int x, y, i, s = 0
    types = [ [0, 1], [1, 0]]
    data = [[...], [...]]
    for i in xrange(1000):
        for x in xrange(2):
            for y in xrange(2):
                if types[x,y] == 0:
                   s+= A(data[x,y]).fun()
                else:
                   s+= B(data[x,y]).fun() 
    return s

基本上，C++ 中的解决方案是使用虚拟方法拥有指向某个基类的指针数组fun()，然后您可以快速迭代它。有没有办法使用 python/cython 来做到这一点？

顺便说一句：将 numpy 的二维数组与 dtype=object_ 一起使用，而不是 python 列表会更快吗？

4

1 回答 1

7

看起来像这样的代码提供了大约 20 倍的加速：

import numpy as np
cimport numpy as np
cdef class Base(object):
    cdef int fun(self):
        return -1

cdef class A(Base):
    cdef int fun(self):
        return 3


cdef class B(Base):
    cdef int fun(self):
        return 2

def test():
    bbb = np.array([[A(), B()], [B(), A()]], dtype=np.object_)
    cdef np.ndarray[dtype=object, ndim=2] a = bbb

    cdef int i, x, y
    cdef int s = 0
    cdef Base u

    for i in xrange(1000):
        for x in xrange(2):
            for y in xrange(2):
                u = a[x,y]                
                s += u.fun()
    return s

它甚至检查 A 和 B 是从 Base 继承的，可能有办法在发布版本中禁用它并获得额外的加速

编辑：检查可以使用删除

u = <Base>a[x,y]
于 2010-10-22T14:35:40.443 回答