coldfusion - 按 dateLastModified 对 cfdirectory 进行分组（日期而非时间）

Question

我正在运行 ColdFusion 9 和 Oracle 数据库。我正在尝试使用以下方法对目录中的所有文件进行分组dateLastModified：

<cfdirectory action="LIST" 
    directory="#path_to_files#" 
    name="res" 
    sort="datelastmodified desc,name ASC" 
    filter="#filters#">

例如：

文件1日期：2016-10-03 11:49:00 am
文件2日期：2016-10-03 07:49:00 am
文件3日期：2016-08-03 07:49:00 am

File 1 & 2应该是第 1 组，File 3应该是第 2 组

如果我使用查询查询，如何根据天数而不是时间比较日期？这是我到目前为止所拥有的，但它似乎不起作用。我没有记录。

    <cfquery name="getfiles" dbtype="query">
        SELECT name, datelastmodified
        FROM   res
        WHERE  CAST( [datelastmodified] as date) = CAST(<cfqueryparam  cfsqltype="CF_SQL_DATE" value="#d#"/> as date)
    </cfquery>

有谁知道根据天而不是时间对文件进行分组的不同方法？

score 2 · Accepted Answer

根据天而不是时间对文件进行分组的方法

要按日期（仅）分组，请将“仅日期”列添加到您的 SELECT 列表中。然后 ORDER BY 新列：

<cfquery name="qSortedFiles" dbtype="query">
    SELECT CAST(DateLastModified AS Date) AS DateOnly
            , Name
            , DateLastModified 
    FROM   getFiles
    ORDER BY DateOnly
</cfquery>

<cfoutput query="qSortedFiles" group="DateOnly">
    #DateOnly#<br>
    <cfoutput>
        - #DateLastModified#<br>
    </cfoutput>
</cfoutput>

我没有记录。

FWIW，原因是尽管使用CAST ... as Date，显然 CF 仍然在内部保留“时间”部分。所以该WHERE子句仍在比较苹果和橙子：

  <!--- comparing Date and Time to Date (only)
  WHERE 2016-08-03 07:49:00 am  = 2016-08-03 00:00:00 am

不要使用相等比较，而是使用以下方法：

    WHERE DateLastModified >= {TheStartDateAtMidnight}
    AND   DateLastModified < {TheNextDayAtMidnight}

这种类型的比较更灵活，因为它适用于日期和时间列 - 以及日期（仅限）。

WHERE  CAST(DateLastModified AS Date) >= <cfqueryparam value="#someDate#" cfsqltype="cf_sql_date">
AND    CAST(DateLastModified AS Date)  < <cfqueryparam value="#dateAdd('d', 1, someDate)#" cfsqltype="cf_sql_date">

score 1 · Accepted Answer

第 1 步 - 使用 cfdirectory 获取查询对象。

第 2 步 - 使用 queryaddcolumn 添加列。

第 3 步 - 循环查询。在新列上使用 querySetCell 和 dateformat

第 4 步 - 使用 cfoutput，按您的新列分组，做您需要做的事情。您的 cfdirectory 标记已经对数据进行了排序。

score 0 · Accepted Answer

所以我想通了。感谢@Dan 和@Leigh 的建议。我用两者作为指南来获得我想要的东西。

我曾经cfdirectory得到一个查询对象。
QueryNew我使用和创建QueryAddRow了一个新查询QuerySetCell。
在新查询的列中包含格式化日期 (mm/dd/yyyy)。确保在设置列名时声明该列为varchar非。dateQueryNew

我使用cfloopandgroup选项cfoutput来显示记录。

<cfset path_to_files = "d:\inetpub\wwwroot\mailrideli\webrpt\">
<cfset filters = "*.pdf|*.txt|*.xls">
<cfdirectory action="LIST" directory="#path_to_files#" name="res" sort="datelastmodified desc,name ASC" filter="#filters#">

<cfset q = QueryNew("Name,dateformated,datelastmodified, size","Varchar, Varchar, date, varchar")>
<cfset count = 1>
<cfset newRow = QueryAddRow(q,res.recordCount)>

<cfloop query="res">
    <cfset d = DateFormat(res.dateLastModified,"mm/dd/yyyy")>
    <cfset temp = QuerySetCell(q, "Name", "#res.name#", count)>
    <cfset temp = QuerySetCell(q, "dateformated", "#d#", count)>
    <cfset temp = QuerySetCell(q, "datelastmodified", "#res.datelastmodified#", count)>
<cfset temp = QuerySetCell(q, "size", "#res.size#", count)>

<cfset count += 1>
</cfloop>

<cfoutput>
    <cfloop query="q" group="dateformated">
                    #q.dateformated#<br />


                    <table>
                        <tr>
                            <th>File Name</th>
                            <th>Size (bytes)</th>
                            <th>Last Modified</th>
                        </tr>
                        <cfloop>

                            <tr>
                                <td><a href="#q.name#">#q.name#</a></td>
                                <td>#q.size#</td>
                                <td>#dateformat(q.dateLastModified, 'mm/dd/yyyy')# #timeformat(q.dateLastModified, 'hh:mm:ssTT')#</td>
                            </tr>

                        </cfloop>
                    </table>
    </cfloop>
    </cfoutput>

我希望它可以帮助那里的任何人。

coldfusion - 按 dateLastModified 对 cfdirectory 进行分组（日期而非时间）

3 回答 3

Related

Reference