2

有人能告诉我为什么下面的代码不起作用吗？它应该在加载时在字段中设置日期，然后允许通过单击该字段来更改日期。我在 linux 上使用 rebol/view 2.7.8。实际上，我认为这段代码在几年前我使用 MS Windows 时可以工作，但由于某种原因不能在 linux 下工作。

博士升

    rebol []
    trace true
    out: layout [
        style dater txt bold right [trans-date/date: copy (form now/date)] 48x24
        dater "T-Date:" trans-date: field 80x24 (form now/date) feel [
            engage: func [face action event][
                if action = 'up [
                    lv-dat: request-date/date/offset (now/date) 450x375
                    if lv-dat <> none [
                        trans-date/text: form lv-dat
                        show trans-date
                    ]
                ]
            ]
            show trans-date
        ]
    ]
    view out
4

1 回答 1

4

这是您的代码的清理版本：

Rebol []

out: layout compose/deep [
    style dater txt bold right 48x24
    dater "T-Date:"
    trans-date: field 80x24 (form now/date) feel [
        engage: func [face action event][
            if action = 'up [
                lv-dat: request-date/date/offset (now/date) 450x375
                if lv-dat [
                    face/text: form lv-dat
                    show face
                ]
            ]
        ]
    ]
]
view out

主要问题是在compose/deep调用之前缺少评估括号表达式layout的调用。但是，这种方法不是初始化人脸属性的常用方法，您应该将初始化代码放在doVID 块的一部分中，如下所示：

Rebol []

out: layout [
    style dater txt bold right 48x24
    dater "T-Date:"
    trans-date: field 80x24 feel [
        engage: func [face action event][
            if action = 'up [
                lv-dat: request-date/date/offset now/date 450x375
                if lv-dat [
                    face/text: form lv-dat
                    show face
                ]
            ]
        ]
    ]
    do [trans-date/text: form now/date]
]
view out

希望这可以帮助。

于 2016-10-02T12:29:18.317 回答